configure.ac

   1 dnl RRDtool AutoConf script ...
   2 dnl ---------------------------
   3 dnl
   4 dnl Created by Jeff Allen, Tobi Oetiker, Blair Zajac
   5 dnl
   6 dnl Inspiration from http://autoconf-archive.cryp.to
   7
   8 dnl tell automake the this script is for rrdtool
   9 dnl the official version number is
  10 dnl a.b.c
  11 AC_INIT([rrdtool],[1.2.19])
  12 dnl for testing a numberical version number comes handy
  13 dnl the released version are
  14 dnl a.bccc
  15 dnl the devl versions will be something like
  16 dnl a.b999yymmddhh
  17 NUMVERS=1.2019
  18 AC_SUBST(NUMVERS)
  19 AC_CANONICAL_TARGET
  20 AM_INIT_AUTOMAKE
  21 AC_CONFIG_HEADERS([rrd_config.h])
  22
  23 dnl all our local stuff like install scripts and include files
  24 dnl is in there
  25
  26
  27 dnl determine the type of system we are running on
  28
  29 AC_SUBST(VERSION)
  30
  31 AC_PREFIX_DEFAULT( /usr/local/rrdtool-$PACKAGE_VERSION )
  32
  33 dnl Minimum Autoconf version required.
  34 AC_PREREQ(2.59)
  35
  36 dnl At the TOP of the HEADER
  37
  38 AH_TOP([
  39
  40 #ifndef RRD_CONFIG_H
  41 #define RRD_CONFIG_H
  42 /* IEEE can be prevented from raising signals with fpsetmask(0) */
  43 #undef MUST_DISABLE_FPMASK
  44
  45 /* IEEE math only works if SIGFPE gets actively set to IGNORE */
  46
  47 #undef MUST_DISABLE_SIGFPE
  48
  49 /* realloc does not support NULL as argument */
  50 #undef NO_NULL_REALLOC
  51
  52  ])
  53
  54 AH_BOTTOM([
  55
  56 /* define strrchr, strchr and memcpy, memmove in terms of bsd funcs
  57    make sure you are NOT using bcopy, index or rindex in the code */
  58
  59 #if STDC_HEADERS
  60 # include <string.h>
  61 #else
  62 # ifndef HAVE_STRCHR
  63 #  define strchr index
  64 #  define strrchr rindex
  65 # endif
  66 char *strchr (), *strrchr ();
  67 # ifndef HAVE_MEMMOVE
  68 #  define memcpy(d, s, n) bcopy ((s), (d), (n))
  69 #  define memmove(d, s, n) bcopy ((s), (d), (n))
  70 # endif
  71 #endif
  72
  73
  74 #if NO_NULL_REALLOC
  75 # define rrd_realloc(a,b) ( (a) == NULL ? malloc( (b) ) : realloc( (a) , (b) ))
  76 #else
  77 # define rrd_realloc(a,b) realloc((a), (b))
  78 #endif
  79
  80 #if NEED_MALLOC_MALLOC_H
  81 #  include <malloc/malloc.h>
  82 #endif
  83
  84 #if HAVE_MATH_H
  85 #  include <math.h>
  86 #endif
  87
  88 #if HAVE_FLOAT_H
  89 #  include <float.h>
  90 #endif
  91
  92 #if HAVE_IEEEFP_H
  93 #  include <ieeefp.h>
  94 #endif
  95
  96 #if HAVE_FP_CLASS_H
  97 #  include <fp_class.h>
  98 #endif
  99
 100 /* for Solaris */
 101 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASS))
 102 #  define HAVE_ISINF 1
 103 #  define isinf(a) (fpclass(a) == FP_NINF || fpclass(a) == FP_PINF)
 104 #endif
 105
 106 /* solaris 10 it defines isnan such that only forte can compile it ... bad bad  */
 107 #if (defined(HAVE_ISNAN) && defined(isnan) && defined(HAVE_FPCLASS))
 108 #  undef isnan
 109 #  define isnan(a) (fpclass(a) == FP_SNAN || fpclass(a) == FP_QNAN)
 110 #endif
 111
 112 /* for OSF1 Digital Unix */
 113 #if (! defined(HAVE_ISINF) && defined(HAVE_FP_CLASS) && defined(HAVE_FP_CLASS_H))
 114 #  define HAVE_ISINF 1
 115 #  define isinf(a) (fp_class(a) == FP_NEG_INF || fp_class(a) == FP_POS_INF)
 116 #endif
 117
 118 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_PLUS_INF) && defined(FP_MINUS_INF))
 119 #  define HAVE_ISINF 1
 120 #  define isinf(a) (fpclassify(a) == FP_MINUS_INF || fpclassify(a) == FP_PLUS_INF)
 121 #endif
 122
 123 #if (! defined(HAVE_ISINF) && defined(HAVE_FPCLASSIFY) && defined(FP_INFINITE))
 124 #  define HAVE_ISINF 1
 125 #  define isinf(a) (fpclassify(a) == FP_INFINITE)
 126 #endif
 127
 128 /* for AIX */
 129 #if (! defined(HAVE_ISINF) && defined(HAVE_CLASS))
 130 #  define HAVE_ISINF 1
 131 #  define isinf(a) (class(a) == FP_MINUS_INF || class(a) == FP_PLUS_INF)
 132 #endif
 133
 134 #if (! defined (HAVE_FINITE) && defined (HAVE_ISFINITE))
 135 #  define HAVE_FINITE 1
 136 #  define finite(a) isfinite(a)
 137 #endif
 138
 139 #if (! defined(HAVE_FINITE) && defined(HAVE_ISNAN) && defined(HAVE_ISINF))
 140 #  define HAVE_FINITE 1
 141 #  define finite(a) (! isnan(a) && ! isinf(a))
 142 #endif
 143
 144 #ifndef HAVE_FINITE
 145 #error "Can't compile without finite function"
 146 #endif
 147
 148 #ifndef HAVE_ISINF
 149 #error "Can't compile without isinf function"
 150 #endif
 151
 152 #endif /* RRD_CONFIG_H */
 153 ])
 154
 155 dnl Process Special Options
 156 dnl -----------------------------------
 157
 158 dnl How the vertical axis label is printed
 159 AC_ARG_VAR(RRDGRAPH_YLEGEND_ANGLE,
 160  [Vertical label angle: 90.0 (default) or 270.0])
 161 AC_DEFINE_UNQUOTED(RRDGRAPH_YLEGEND_ANGLE,${RRDGRAPH_YLEGEND_ANGLE:-90.0},
 162  [Vertical label angle: 90.0 (default) or 270.0])
 163
 164 AC_ARG_ENABLE(rrdcgi,[  --disable-rrdcgi        disable building of rrdcgi],
 165 [],[enable_rrdcgi=yes])
 166
 167 dnl Check if we run on a system that has fonts
 168 AC_ARG_WITH(rrd-default-font,
 169 [  --with-rrd-default-font=[OPTIONS]  set the full path to your default font.],
 170 [RRD_DEFAULT_FONT=$withval],[
 171   if test -d ${WINDIR:-nodir}/cour.ttf ; then
 172         RRD_DEFAULT_FONT=`cd $WINDIR;pwd`/cour.ttf
 173   else
 174         RRD_DEFAULT_FONT='$(fontsdir)/$(fonts_DATA)'
 175   fi
 176 ])
 177
 178 dnl Use mmap in rrd_update instead of seek+write
 179 AC_ARG_ENABLE([mmap],
 180 [  --disable-mmap          disable mmap in rrd_update, use seek+write instead],
 181 [],
 182 [enable_mmap=yes])
 183
 184
 185  AC_ARG_ENABLE(pthread,[  --disable-pthread       disable multithread support],
 186 [],[enable_pthread=yes])
 187
 188
 189
 190 CONFIGURE_PART(Audit Compilation Environment)
 191
 192
 193 dnl Check for the compiler and static/shared library creation.
 194 AC_PROG_CC
 195 AC_PROG_CPP
 196 AC_PROG_LIBTOOL
 197
 198 dnl which flags does the compile support?
 199 if test "$GCC" = "yes"; then
 200   for flag in -fno-strict-aliasing -Wall -std=gnu99 -pedantic -Wshadow -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations -Wnested-externs -Winline -W; do
 201     oCFLAGS=$CFLAGS
 202     CFLAGS="$CFLAGS $flag"
 203     cachename=rd_cv_gcc_flag_`echo $flag|sed 's/[[^A-Za-z]]/_/g'`
 204     AC_CACHE_CHECK([if gcc likes the $flag flag], $cachename,
 205        [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[return 0 ]])],[eval $cachename=yes],[eval $cachename=no])])
 206     if eval test \$$cachename = no; then
 207          CFLAGS=$oCFLAGS
 208     fi
 209   done
 210 fi
 211
 212
 213
 214 AC_SUBST(RRD_DEFAULT_FONT)
 215
 216 CONFIGURE_PART(Checking for Header Files)
 217
 218 dnl Checks for header files.
 219 AC_HEADER_STDC
 220 AC_HEADER_DIRENT
 221 AC_CHECK_HEADERS(sys/stat.h sys/types.h fcntl.h time.h locale.h fp_class.h malloc.h unistd.h ieeefp.h math.h sys/time.h sys/times.h sys/param.h sys/resource.h float.h)
 222
 223 dnl Checks for typedefs, structures, and compiler characteristics.
 224 AC_C_CONST
 225 AC_HEADER_TIME
 226 AC_STRUCT_TM
 227
 228 dnl Checks for libraries.
 229 AC_CHECK_FUNC(acos, , AC_CHECK_LIB(m, acos))
 230
 231 dnl add pic flag in any case this makes sure all our code is relocatable
 232 eval `./libtool --config | grep pic_flag`
 233 CFLAGS="$CFLAGS $pic_flag"
 234
 235 CONFIGURE_PART(Test Library Functions)
 236
 237 dnl Checks for library functions.
 238 AC_FUNC_STRFTIME
 239 AC_FUNC_VPRINTF
 240
 241 AC_C_BIGENDIAN
 242
 243 dnl for each function found we get a definition in config.h
 244 dnl of the form HAVE_FUNCTION
 245
 246 AC_CHECK_FUNCS(tzset mbstowcs opendir readdir chdir chroot getuid setlocale strerror strerror_r snprintf vsnprintf fpclass class fp_class isnan memmove strchr mktime getrusage gettimeofday)
 247
 248
 249 if test "x$enable_mmap" = xyes; then
 250   case "$host" in
 251     *cygwin*)
 252        # the normal mmap test does not work in cygwin
 253        AC_CHECK_FUNCS(mmap)
 254        if [ "x${ac_cv_func_mmap}" = xyes ]; then
 255          ac_cv_func_mmap_fixed_mapped=yes
 256        fi
 257     ;;
 258     *)
 259        AC_FUNC_MMAP
 260     ;;
 261   esac
 262 fi
 263
 264
 265 CONFIGURE_PART(IEEE Math Checks)
 266
 267 dnl HP-UX 11.00 does not have finite but does have isfinite as a macro so we need
 268 dnl actual code to check if this works
 269 AC_CHECK_FUNCS(fpclassify, ,
 270   [AC_MSG_CHECKING(for fpclassify with <math.h>)
 271     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 272 volatile int x;volatile float f; ]], [[x = fpclassify(f)]])],[AC_MSG_RESULT(yes)
 273       AC_DEFINE(HAVE_FPCLASSIFY)],[AC_MSG_RESULT(no)])])
 274 AC_CHECK_FUNCS(finite, ,
 275   [AC_CHECK_FUNCS(isfinite, ,
 276     [AC_MSG_CHECKING(for isfinite with <math.h>)
 277     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 278 volatile int x;volatile float f;  ]], [[x = isfinite(f)]])],[AC_MSG_RESULT(yes)
 279       AC_DEFINE(HAVE_ISFINITE)],[AC_MSG_RESULT(no)])])])
 280 AC_CHECK_FUNCS(isinf, ,
 281   [AC_MSG_CHECKING(for isinf with <math.h>)
 282     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>
 283 volatile int x;volatile float f;  ]], [[x = isinf(f)]])],[AC_MSG_RESULT(yes)
 284       AC_DEFINE(HAVE_ISINF)],[AC_MSG_RESULT(no)])])
 285
 286 AC_FULL_IEEE
 287
 288 CONFIGURE_PART(Resolve Portability Issues)
 289
 290 dnl what does realloc do if it gets called with a NULL pointer
 291
 292 AC_CACHE_CHECK([if realloc can deal with NULL], rd_cv_null_realloc,
 293 [AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 294               int main(void){
 295               char *x = NULL;
 296               x = realloc (x,10);
 297               if (x==NULL) return 1;
 298               return 0;
 299              }]])],[rd_cv_null_realloc=yes],[rd_cv_null_realloc=nope],[:])])
 300
 301 if test x"$rd_cv_null_realloc" = xnope; then
 302 AC_DEFINE(NO_NULL_REALLOC)
 303 fi
 304
 305 AC_LANG_PUSH(C)
 306 dnl solaris has some odd defines it needs in order to propperly compile ctime_r
 307 AC_MSG_CHECKING([if ctime_r need special care to act posixly correct])
 308 AC_LINK_IFELSE(
 309     AC_LANG_PROGRAM(
 310            [[#include <time.h>]],
 311            [[ctime_r(NULL,NULL,0)]]
 312                    ),
 313     [ CPPFLAGS="$CPPFLAGS -D_POSIX_PTHREAD_SEMANTICS"
 314       AC_LINK_IFELSE(
 315           AC_LANG_PROGRAM(
 316                 [[#include <time.h>]],
 317                 [[ctime_r(NULL,NULL)]]
 318                          ),
 319           [AC_MSG_RESULT([yes, this seems to be solaris style])],
 320           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 321       )
 322     ],
 323     [ AC_LINK_IFELSE(
 324           AC_LANG_PROGRAM(
 325                 [[#include <time.h>]],
 326                 [[ctime_r(NULL,NULL)]]
 327                          ),
 328           [AC_MSG_RESULT(no)],
 329           [AC_MSG_ERROR([Can't figure how to compile ctime_r])]
 330       )
 331     ]
 332 )
 333 AC_LANG_POP(C)
 334
 335 dnl Check for pthreads
 336 dnl http://autoconf-archive.cryp.to/acx_pthread.m4
 337
 338 AC_SUBST(MULTITHREAD_CFLAGS)
 339 AC_SUBST(MULTITHREAD_LDFLAGS)
 340
 341 if test $enable_pthread != no; then
 342  ACX_PTHREAD([
 343     MULTITHREAD_CFLAGS=$PTHREAD_CFLAGS
 344     MULTITHREAD_LDFLAGS=$PTHREAD_LIBS
 345              ],
 346              [])
 347 fi
 348
 349 dnl since we use lots of *_r functions all over the code we better
 350 dnl make sure they are known
 351
 352 if test  "x$x_rflag" != "xno"; then
 353    CPPFLAGS="$CPPFLAGS $x_rflag"
 354 fi
 355
 356 AM_CONDITIONAL(BUILD_MULTITHREAD,[test $enable_pthread != no])
 357
 358 AC_LANG_PUSH(C)
 359 dnl see if we have to include malloc/malloc.h
 360 AC_MSG_CHECKING([do we need malloc/malloc.h])
 361 AC_LINK_IFELSE(
 362     AC_LANG_PROGRAM(
 363            [[#include <stdlib.h>]],
 364            [[malloc(1)]]
 365                    ),
 366     [ AC_MSG_RESULT([nope, works out of the box]) ],
 367     [ AC_LINK_IFELSE(
 368           AC_LANG_PROGRAM(
 369                 [[#include <stdlib.h>
 370                   #include <malloc/malloc.h>]],
 371                 [[malloc(1)]]
 372                          ),
 373           [AC_DEFINE(NEED_MALLOC_MALLOC_H)
 374            AC_MSG_RESULT([yes we do])],
 375           [AC_MSG_ERROR([Can not figure how to compile malloc])]
 376       )
 377     ]
 378 )
 379 AC_LANG_POP(C)
 380
 381 CONFIGURE_PART(Findr 3rd-Party Libraries)
 382
 383
 384 AM_CONDITIONAL(BUILD_RRDCGI,[test $enable_rrdcgi != no])
 385
 386 CORE_LIBS="$LIBS"
 387
 388 EX_CHECK_ALL(art_lgpl_2, art_vpath_add_point,       libart_lgpl/libart.h,   libart-2.0,  2.3.17, ftp://ftp.gnome.org/pub/GNOME/sources/libart_lgpl/2.3/, /usr/include/libart-2.0)
 389 EX_CHECK_ALL(z,          zlibVersion,               zlib.h,                 zlib,        1.2.3,  http://www.gzip.org/zlib/, "")
 390 EX_CHECK_ALL(png,        png_access_version_number, png.h,                  libpng,      1.2.10,  http://prdownloads.sourceforge.net/libpng/, "")
 391 EX_CHECK_ALL(freetype,   FT_Init_FreeType,          ft2build.h,             freetype2,   2.1.10,  http://prdownloads.sourceforge.net/freetype/, /usr/include/freetype2)
 392
 393 if test "$EX_CHECK_ALL_ERR" = "YES"; then
 394   AC_MSG_ERROR([Please fix the library issues listed above and try again.])
 395 fi
 396
 397 ALL_LIBS="$LIBS"
 398 LIBS=
 399
 400 AC_SUBST(CORE_LIBS)
 401 AC_SUBST(ALL_LIBS)
 402
 403 CONFIGURE_PART(Prep for Building Language Bindings)
 404
 405 dnl Check for Perl.
 406 AC_PATH_PROG(PERL, perl, no)
 407
 408 AC_ARG_ENABLE(perl,[  --disable-perl          do not build the perl modules],
 409 [],[enable_perl=yes])
 410
 411
 412 AC_ARG_VAR(PERLCC, [[] C compiler for Perl modules])
 413 AC_ARG_VAR(PERLCCFLAGS, [[] CC flags for Perl modules])
 414 AC_ARG_VAR(PERLLD, [[same as PERLCC] Linker for Perl modules])
 415 AC_ARG_VAR(PERLLDFLAGS, [[] LD flags for Perl modules])
 416
 417 if test "x$PERL" = "xno" -o  x$enable_perl = xno; then
 418         COMP_PERL=
 419 else
 420         COMP_PERL="perl_piped perl_shared"
 421         AC_MSG_CHECKING(for the perl version you are running)
 422         PERL_VERSION=`$PERL -MConfig -e 'print $Config{version}'`
 423         AC_MSG_RESULT($PERL_VERSION)
 424         if test -z "$PERLCC"; then
 425             AC_MSG_CHECKING(for the C compiler perl wants to use to build its modules)
 426             perlcc=`$PERL -MConfig -e 'print $Config{cc}'`
 427             AC_MSG_RESULT($perlcc)
 428             if test ! -x "$perlcc"; then
 429                 AC_PATH_PROG(PERL_CC, "${perlcc}", no)
 430                 if test "$PERL_CC" = "no"; then
 431                     AC_MSG_WARN([
 432 I would not find the Compiler ($perlcc) that was originally used to compile
 433 your perl binary. You should either make sure that this compiler is
 434 available on your system, pick an other compiler and set PERLCC
 435 appropriately, or use a different perl setup that was compiled locally.
 436
 437 I will disable the compilation of the RRDs perl module for now.
 438 ])
 439                     COMP_PERL="perl_piped"
 440                 fi
 441             fi
 442         fi
 443 fi
 444
 445 AC_MSG_CHECKING(Perl Modules to build)
 446 AC_MSG_RESULT(${COMP_PERL:-No Perl Modules will be built})
 447
 448 # Options to pass when configuring perl module
 449 ppref=$prefix
 450 test "$ppref" = "NONE" && ppref=$ac_default_prefix
 451
 452 PERL_MAKE_OPTIONS="PREFIX=$ppref LIB=$ppref/lib/perl/$PERL_VERSION"
 453
 454 dnl pass additional perl options when generating Makefile from Makefile.PL
 455 AC_ARG_ENABLE(perl-site-install,
 456 [  --enable-perl-site-install   by default the rrdtool perl modules are installed
 457                           together with rrdtool in $prefix/lib/perl. You have to
 458                           put a 'use lib qw($prefix/lib/perl)' into your scripts
 459                           when you want to use them. When you set this option
 460                           the perl modules will get installed wherever
 461                           your perl setup thinks it is best.],
 462 [PERL_MAKE_OPTIONS=],[])
 463
 464 if test ! -z "$PERLCC"; then
 465    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CC=$PERLCC"
 466
 467    if test ! -z "$PERLCCFLAGS"; then
 468        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS CCFLAGS=$PERLCCFLAGS"
 469    fi
 470
 471    if test -z "$PERLLD"; then
 472        PERLLD=$PERLCC
 473    fi
 474    PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LD=$PERLLD"
 475
 476    if test ! -z "$PERLLDFLAGS"; then
 477        PERL_MAKE_OPTIONS="$PERL_MAKE_OPTIONS LDFLAGS=$PERLLDFLAGS"
 478    fi
 479 fi
 480
 481 AC_ARG_WITH(perl-options,
 482 [  --with-perl-options=[OPTIONS]  options to pass on command-line when
 483                           generating Makefile from Makefile.PL. If you set this
 484                           option, interesting things may happen unless you know
 485                           what you are doing!],
 486 [PERL_MAKE_OPTIONS=$withval])
 487
 488 AC_SUBST(PERL_MAKE_OPTIONS)
 489 AC_SUBST(PERL)
 490 AC_SUBST(COMP_PERL)
 491 AC_SUBST(PERL_VERSION)
 492
 493 dnl Check for Ruby.
 494 AC_PATH_PROG(RUBY, ruby, no)
 495
 496 AC_ARG_ENABLE(ruby,[  --disable-ruby          do not build the ruby modules],
 497 [],[enable_ruby=yes])
 498
 499
 500 if test "x$RUBY" = "xno" -o  x$enable_ruby = xno; then
 501         COMP_RUBY=
 502 else
 503         COMP_RUBY="ruby"
 504
 505 fi
 506
 507
 508 AC_MSG_CHECKING(Ruby Modules to build)
 509 AC_MSG_RESULT(${COMP_RUBY:-No Ruby Modules will be built})
 510
 511 dnl pass additional ruby options when generating Makefile from Makefile.PL
 512 AC_ARG_ENABLE(ruby-site-install,
 513 [  --enable-ruby-site-install   by default the rrdtool ruby modules are installed
 514                           together with rrdtool in $prefix/lib/ruby. You have to
 515                           add $prefix/lib/ruby/$ruby_version/$sitearch to you $: variable
 516                           for ruby to find the RRD.so file.],
 517 [RUBY_MAKE_OPTIONS=],[RUBY_MAKE_OPTIONS="sitedir=$prefix/lib/ruby"])
 518
 519
 520 AC_ARG_WITH(ruby-options,
 521 [  --with-ruby-options=[OPTIONS]  options to pass on command-line when
 522                           generating Makefile from extconf.rb. If you set this
 523                           option, interesting things may happen unless you know
 524                           what you are doing!],
 525 [RUBY_MAKE_OPTIONS=$withval])
 526
 527 AC_SUBST(RUBY_MAKE_OPTIONS)
 528 AC_SUBST(RUBY)
 529 AC_SUBST(COMP_RUBY)
 530
 531
 532 enable_tcl_site=no
 533
 534 AC_ARG_ENABLE(tcl,[  --disable-tcl           do not build the tcl modules],
 535 [],[enable_tcl=yes])
 536
 537 if test  "$enable_tcl" = "yes"; then
 538   dnl Check for Tcl.
 539   withval=""
 540   AC_ARG_WITH(tcllib,[  --with-tcllib=DIR       location of the tclConfig.sh])
 541   enable_tcl=no
 542   for dir in $withval /usr/lib /usr/local/lib; do
 543     AC_MSG_CHECKING(for tclConfig.sh in $dir)
 544     if test -f "$dir/tclConfig.sh" ; then
 545         tcl_config=$dir/tclConfig.sh
 546         enable_tcl=yes
 547         AC_MSG_RESULT(yes)
 548         break
 549     else
 550         AC_MSG_RESULT(no)
 551     fi
 552   done
 553
 554   if test "$enable_tcl" = "no"; then
 555         AC_MSG_WARN([tclConfig.sh not found - Tcl interface won't be built])
 556   else
 557         . $tcl_config
 558         TCL_PACKAGE_DIR="$TCL_PACKAGE_PATH/tclrrd$VERSION"
 559   fi
 560   AC_ARG_ENABLE(tcl,[  --enable-tcl-site        install the tcl extension in the tcl tree],
 561   [],[enable_tcl_site=yes])
 562
 563 fi
 564
 565 AM_CONDITIONAL(BUILD_TCL, test "$enable_tcl" = "yes" )
 566 AM_CONDITIONAL(BUILD_TCL_SITE, test "$enable_tcl_site" = "yes" )
 567
 568 AC_SUBST(TCL_PREFIX)
 569 AC_SUBST(TCL_SHLIB_CFLAGS)
 570 AC_SUBST(TCL_SHLIB_LD)
 571 AC_SUBST(TCL_SHLIB_SUFFIX)
 572 AC_SUBST(TCL_PACKAGE_PATH)
 573 AC_SUBST(TCL_LD_SEARCH_FLAGS)
 574 AC_SUBST(TCL_STUB_LIB_SPEC)
 575 AC_SUBST(TCL_VERSION)
 576 AC_SUBST(TCL_PACKAGE_DIR)
 577
 578 AC_ARG_ENABLE(python,[  --disable-python        do not build the python modules],
 579 [],[enable_python=yes])
 580
 581 if test  "$enable_python" = "yes"; then
 582 dnl Check for python
 583 AM_PATH_PYTHON(2.3,[],[enable_python=no])
 584 AM_CHECK_PYTHON_HEADERS(,[enable_python=no;AC_MSG_WARN(could not find Python headers)])
 585 fi
 586
 587 if test  x$enable_python = xno; then
 588         COMP_PYTHON=
 589 else
 590         COMP_PYTHON="python"
 591 fi
 592
 593 AC_SUBST(COMP_PYTHON)
 594
 595 dnl Check for nroff
 596 AC_PATH_PROGS(NROFF, gnroff nroff)
 597 AC_PATH_PROGS(TROFF, groff troff)
 598
 599 AC_ARG_VAR(RRDDOCDIR, [[DATADIR/doc/PACKAGE-VERSION] Documentation directory])
 600 if test -z "$RRDDOCDIR"; then
 601    RRDDOCDIR='${datadir}/doc/${PACKAGE}-${VERSION}'; fi
 602
 603
 604 CONFIGURE_PART(Apply Configuration Information)
 605
 606 AC_CONFIG_FILES([examples/shared-demo.pl])
 607 AC_CONFIG_FILES([examples/piped-demo.pl])
 608 AC_CONFIG_FILES([examples/stripes.pl])
 609 AC_CONFIG_FILES([examples/bigtops.pl])
 610 AC_CONFIG_FILES([examples/minmax.pl])
 611 AC_CONFIG_FILES([examples/4charts.pl])
 612 AC_CONFIG_FILES([examples/perftest.pl])
 613 AC_CONFIG_FILES([examples/Makefile])
 614 AC_CONFIG_FILES([doc/Makefile])
 615 AC_CONFIG_FILES([src/Makefile])
 616 AC_CONFIG_FILES([bindings/Makefile])
 617 AC_CONFIG_FILES([bindings/tcl/Makefile])
 618 AC_CONFIG_FILES([bindings/tcl/ifOctets.tcl])
 619 AC_CONFIG_FILES([bindings/python/Makefile])
 620 AC_CONFIG_FILES([Makefile])
 621
 622 AC_CONFIG_COMMANDS([default],[[ chmod +x examples/*.pl]],[[]])
 623 AC_OUTPUT
 624
 625 AC_MSG_CHECKING(in)
 626 AC_MSG_RESULT(and out again)
 627
 628 echo $ECHO_N "ordering CD from http://tobi.oetiker.ch/wish $ECHO_C" 1>&6
 629 sleep 1
 630 echo $ECHO_N ".$ECHO_C" 1>&6
 631 sleep 1
 632 echo $ECHO_N ".$ECHO_C" 1>&6
 633 sleep 1
 634 echo $ECHO_N ".$ECHO_C" 1>&6
 635 sleep 1
 636 echo $ECHO_N ".$ECHO_C" 1>&6
 637 sleep 1
 638 AC_MSG_RESULT([ just kidding ;-)])
 639 echo
 640 echo "----------------------------------------------------------------"
 641 echo "Config is DONE!"
 642 echo
 643 echo "          With MMAP IO: $ac_cv_func_mmap_fixed_mapped"
 644 echo "          Perl Modules: $COMP_PERL"
 645 echo "           Perl Binary: $PERL"
 646 echo "          Perl Version: $PERL_VERSION"
 647 echo "          Perl Options: $PERL_MAKE_OPTIONS"
 648 echo "          Ruby Modules: $COMP_RUBY"
 649 echo "           Ruby Binary: $RUBY"
 650 echo "          Ruby Options: $RUBY_MAKE_OPTIONS"
 651 echo "    Build Tcl Bindings: $enable_tcl"
 652 echo " Build Python Bindings: $enable_python"
 653 echo "          Build rrdcgi: $enable_rrdcgi"
 654 echo "       Build librrd MT: $enable_pthread"
 655 echo
 656 echo
 657 echo "Type 'make' to compile the software and use 'make install' to "
 658 echo "install everything to: $prefix."
 659 echo
 660 echo "       ... that wishlist is NO JOKE. If you find RRDtool useful"
 661 echo "make me happy. Go to http://tobi.oetiker.ch/wish and"
 662 echo "place an order."
 663 echo
 664 echo "                               -- Tobi Oetiker <tobi@oetiker.ch>"
 665 echo "----------------------------------------------------------------"