git-svnimport.perl

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to pull and analyze SVN changes.
   7 #
   8 # Checking out the files is done by a single long-running SVN connection.
   9 #
  10 # The head revision is on branch "origin" by default.
  11 # You can change that with the '-o' option.
  12
  13 require 5.008; # for shell-safe open("-|",LIST)
  14 use strict;
  15 use warnings;
  16 use Getopt::Std;
  17 use File::Spec;
  18 use File::Temp qw(tempfile);
  19 use File::Path qw(mkpath);
  20 use File::Basename qw(basename dirname);
  21 use Time::Local;
  22 use IO::Pipe;
  23 use POSIX qw(strftime dup2);
  24 use IPC::Open2;
  25 use SVN::Core;
  26 use SVN::Ra;
  27
  28 die "Need CVN:Core 1.2.1 or better" if $SVN::Core::VERSION lt "1.2.1";
  29
  30 $SIG{'PIPE'}="IGNORE";
  31 $ENV{'TZ'}="UTC";
  32
  33 our($opt_h,$opt_o,$opt_v,$opt_u,$opt_C,$opt_i,$opt_m,$opt_M,$opt_t,$opt_T,$opt_b,$opt_s,$opt_l,$opt_d,$opt_D);
  34
  35 sub usage() {
  36         print STDERR <<END;
  37 Usage: ${\basename $0}     # fetch/update GIT from CVS
  38        [-o branch-for-HEAD] [-h] [-v] [-l max_num_changes]
  39        [-C GIT_repository] [-t tagname] [-T trunkname] [-b branchname]
  40        [-d|-D] [-i] [-u] [-s start_chg] [-m] [-M regex] [SVN_URL]
  41 END
  42         exit(1);
  43 }
  44
  45 getopts("b:C:dDhil:mM:o:s:t:T:uv") or usage();
  46 usage if $opt_h;
  47
  48 my $tag_name = $opt_t || "tags";
  49 my $trunk_name = $opt_T || "trunk";
  50 my $branch_name = $opt_b || "branches";
  51
  52 @ARGV == 1 or @ARGV == 2 or usage();
  53
  54 $opt_o ||= "origin";
  55 $opt_s ||= 1;
  56 $opt_l = 100 unless defined $opt_l;
  57 my $git_tree = $opt_C;
  58 $git_tree ||= ".";
  59
  60 my $svn_url = $ARGV[0];
  61 my $svn_dir = $ARGV[1];
  62
  63 our @mergerx = ();
  64 if ($opt_m) {
  65         @mergerx = ( qr/\W(?:from|of|merge|merging|merged) (\w+)/i );
  66 }
  67 if ($opt_M) {
  68         push (@mergerx, qr/$opt_M/);
  69 }
  70
  71 select(STDERR); $|=1; select(STDOUT);
  72
  73
  74 package SVNconn;
  75 # Basic SVN connection.
  76 # We're only interested in connecting and downloading, so ...
  77
  78 use File::Spec;
  79 use File::Temp qw(tempfile);
  80 use POSIX qw(strftime dup2);
  81
  82 sub new {
  83         my($what,$repo) = @_;
  84         $what=ref($what) if ref($what);
  85
  86         my $self = {};
  87         $self->{'buffer'} = "";
  88         bless($self,$what);
  89
  90         $repo =~ s#/+$##;
  91         $self->{'fullrep'} = $repo;
  92         $self->conn();
  93
  94         return $self;
  95 }
  96
  97 sub conn {
  98         my $self = shift;
  99         my $repo = $self->{'fullrep'};
 100         my $s = SVN::Ra->new($repo);
 101
 102         die "SVN connection to $repo: $!\n" unless defined $s;
 103         $self->{'svn'} = $s;
 104         $self->{'repo'} = $repo;
 105         $self->{'maxrev'} = $s->get_latest_revnum();
 106 }
 107
 108 sub file {
 109         my($self,$path,$rev) = @_;
 110
 111         my ($fh, $name) = tempfile('gitsvn.XXXXXX',
 112                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 113
 114         print "... $rev $path ...\n" if $opt_v;
 115         my $pool = SVN::Pool->new();
 116         eval { $self->{'svn'}->get_file($path,$rev,$fh,$pool); };
 117         $pool->clear;
 118         if($@) {
 119                 return undef if $@ =~ /Attempted to get checksum/;
 120                 die $@;
 121         }
 122         close ($fh);
 123
 124         return $name;
 125 }
 126
 127 package main;
 128 use URI;
 129
 130 my $svn = $svn_url;
 131 $svn .= "/$svn_dir" if defined $svn_dir;
 132 $svn = SVNconn->new($svn);
 133
 134 my $lwp_ua;
 135 if($opt_d or $opt_D) {
 136         $svn_url = URI->new($svn_url)->canonical;
 137         if($opt_D) {
 138                 $svn_dir =~ s#/*$#/#;
 139         } else {
 140                 $svn_dir = "";
 141         }
 142         if ($svn_url->scheme eq "http") {
 143                 use LWP::UserAgent;
 144                 $lwp_ua = LWP::UserAgent->new(keep_alive => 1, requests_redirectable => []);
 145         } else {
 146                 print STDERR "Warning: not HTTP; turning off direct file access\n";
 147                 $opt_d=0;
 148         }
 149 }
 150
 151 sub pdate($) {
 152         my($d) = @_;
 153         $d =~ m#(\d\d\d\d)-(\d\d)-(\d\d)T(\d\d):(\d\d):(\d\d)#
 154                 or die "Unparseable date: $d\n";
 155         my $y=$1; $y-=1900 if $y>1900;
 156         return timegm($6||0,$5,$4,$3,$2-1,$y);
 157 }
 158
 159 sub getwd() {
 160         my $pwd = `pwd`;
 161         chomp $pwd;
 162         return $pwd;
 163 }
 164
 165
 166 sub get_headref($$) {
 167     my $name    = shift;
 168     my $git_dir = shift;
 169     my $sha;
 170
 171     if (open(C,"$git_dir/refs/heads/$name")) {
 172         chomp($sha = <C>);
 173         close(C);
 174         length($sha) == 40
 175             or die "Cannot get head id for $name ($sha): $!\n";
 176     }
 177     return $sha;
 178 }
 179
 180
 181 -d $git_tree
 182         or mkdir($git_tree,0777)
 183         or die "Could not create $git_tree: $!";
 184 chdir($git_tree);
 185
 186 my $orig_branch = "";
 187 my $forward_master = 0;
 188 my %branches;
 189
 190 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 191 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 192 $ENV{"GIT_DIR"} = $git_dir;
 193 my $orig_git_index;
 194 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 195 my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 196                                     DIR => File::Spec->tmpdir());
 197 close ($git_ih);
 198 $ENV{GIT_INDEX_FILE} = $git_index;
 199 my $maxnum = 0;
 200 my $last_rev = "";
 201 my $last_branch;
 202 my $current_rev = $opt_s-1;
 203 unless(-d $git_dir) {
 204         system("git-init-db");
 205         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 206         system("git-read-tree");
 207         die "Cannot init an empty tree: $?\n" if $?;
 208
 209         $last_branch = $opt_o;
 210         $orig_branch = "";
 211 } else {
 212         -f "$git_dir/refs/heads/$opt_o"
 213                 or die "Branch '$opt_o' does not exist.\n".
 214                        "Either use the correct '-o branch' option,\n".
 215                        "or import to a new repository.\n";
 216
 217         -f "$git_dir/svn2git"
 218                 or die "'$git_dir/svn2git' does not exist.\n".
 219                        "You need that file for incremental imports.\n";
 220         $last_branch = basename(readlink("$git_dir/HEAD"));
 221         unless($last_branch) {
 222                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 223                 $last_branch = "master";
 224         }
 225         $orig_branch = $last_branch;
 226         $last_rev = get_headref($orig_branch, $git_dir);
 227         if (-f "$git_dir/SVN2GIT_HEAD") {
 228                 die <<EOM;
 229 SVN2GIT_HEAD exists.
 230 Make sure your working directory corresponds to HEAD and remove SVN2GIT_HEAD.
 231 You may need to run
 232
 233     git-read-tree -m -u SVN2GIT_HEAD HEAD
 234 EOM
 235         }
 236         system('cp', "$git_dir/HEAD", "$git_dir/SVN2GIT_HEAD");
 237
 238         $forward_master =
 239             $opt_o ne 'master' && -f "$git_dir/refs/heads/master" &&
 240             system('cmp', '-s', "$git_dir/refs/heads/master",
 241                                 "$git_dir/refs/heads/$opt_o") == 0;
 242
 243         # populate index
 244         system('git-read-tree', $last_rev);
 245         die "read-tree failed: $?\n" if $?;
 246
 247         # Get the last import timestamps
 248         open my $B,"<", "$git_dir/svn2git";
 249         while(<$B>) {
 250                 chomp;
 251                 my($num,$branch,$ref) = split;
 252                 $branches{$branch}{$num} = $ref;
 253                 $branches{$branch}{"LAST"} = $ref;
 254                 $current_rev = $num if $current_rev < $num;
 255         }
 256         close($B);
 257 }
 258 -d $git_dir
 259         or die "Could not create git subdir ($git_dir).\n";
 260
 261 open BRANCHES,">>", "$git_dir/svn2git";
 262
 263 sub node_kind($$$) {
 264         my ($branch, $path, $revision) = @_;
 265         my $pool=SVN::Pool->new;
 266         my $kind = $svn->{'svn'}->check_path(revert_split_path($branch,$path),$revision,$pool);
 267         $pool->clear;
 268         return $kind;
 269 }
 270
 271 sub revert_split_path($$) {
 272         my($branch,$path) = @_;
 273
 274         my $svnpath;
 275         $path = "" if $path eq "/"; # this should not happen, but ...
 276         if($branch eq "/") {
 277                 $svnpath = "$trunk_name/$path";
 278         } elsif($branch =~ m#^/#) {
 279                 $svnpath = "$tag_name$branch/$path";
 280         } else {
 281                 $svnpath = "$branch_name/$branch/$path";
 282         }
 283
 284         return $svnpath
 285 }
 286
 287 sub get_file($$$) {
 288         my($rev,$branch,$path) = @_;
 289
 290         my $svnpath = revert_split_path($branch,$path);
 291
 292         # now get it
 293         my $name;
 294         if($opt_d) {
 295                 my($req,$res);
 296
 297                 # /svn/!svn/bc/2/django/trunk/django-docs/build.py
 298                 my $url=$svn_url->clone();
 299                 $url->path($url->path."/!svn/bc/$rev/$svn_dir$svnpath");
 300                 print "... $path...\n" if $opt_v;
 301                 $req = HTTP::Request->new(GET => $url);
 302                 $res = $lwp_ua->request($req);
 303                 if ($res->is_success) {
 304                         my $fh;
 305                         ($fh, $name) = tempfile('gitsvn.XXXXXX',
 306                         DIR => File::Spec->tmpdir(), UNLINK => 1);
 307                         print $fh $res->content;
 308                         close($fh) or die "Could not write $name: $!\n";
 309                 } else {
 310                         return undef if $res->code == 301; # directory?
 311                         die $res->status_line." at $url\n";
 312                 }
 313         } else {
 314                 $name = $svn->file("/$svnpath",$rev);
 315                 return undef unless defined $name;
 316         }
 317
 318         open my $F, '-|', "git-hash-object", "-w", $name
 319                 or die "Cannot create object: $!\n";
 320         my $sha = <$F>;
 321         chomp $sha;
 322         close $F;
 323         unlink $name;
 324         my $mode = "0644"; # SV does not seem to store any file modes
 325         return [$mode, $sha, $path];
 326 }
 327
 328 sub split_path($$) {
 329         my($rev,$path) = @_;
 330         my $branch;
 331
 332         if($path =~ s#^/\Q$tag_name\E/([^/]+)/?##) {
 333                 $branch = "/$1";
 334         } elsif($path =~ s#^/\Q$trunk_name\E/?##) {
 335                 $branch = "/";
 336         } elsif($path =~ s#^/\Q$branch_name\E/([^/]+)/?##) {
 337                 $branch = $1;
 338         } else {
 339                 my %no_error = (
 340                         "/" => 1,
 341                         "/$tag_name" => 1,
 342                         "/$branch_name" => 1
 343                 );
 344                 print STDERR "$rev: Unrecognized path: $path\n" unless (defined $no_error{$path});
 345                 return ()
 346         }
 347         $path = "/" if $path eq "";
 348         return ($branch,$path);
 349 }
 350
 351 sub branch_rev($$) {
 352
 353         my ($srcbranch,$uptorev) = @_;
 354
 355         my $bbranches = $branches{$srcbranch};
 356         my @revs = reverse sort { ($a eq 'LAST' ? 0 : $a) <=> ($b eq 'LAST' ? 0 : $b) } keys %$bbranches;
 357         my $therev;
 358         foreach my $arev(@revs) {
 359                 next if  ($arev eq 'LAST');
 360                 if ($arev <= $uptorev) {
 361                         $therev = $arev;
 362                         last;
 363                 }
 364         }
 365         return $therev;
 366 }
 367
 368 sub copy_path($$$$$$$) {
 369         # Somebody copied a whole subdirectory.
 370         # We need to find the index entries from the old version which the
 371         # SVN log entry points to, and add them to the new place.
 372
 373         my($newrev,$newbranch,$path,$oldpath,$rev,$node_kind,$new) = @_;
 374
 375         my($srcbranch,$srcpath) = split_path($rev,$oldpath);
 376         my $therev = branch_rev($srcbranch, $rev);
 377         my $gitrev = $branches{$srcbranch}{$therev};
 378         unless($gitrev) {
 379                 print STDERR "$newrev:$newbranch: could not find $oldpath \@ $rev\n";
 380                 return;
 381         }
 382         print "$newrev:$newbranch:$path: copying from $srcbranch:$srcpath @ $rev\n" if $opt_v;
 383         if ($node_kind eq $SVN::Node::dir) {
 384                         $srcpath =~ s#/*$#/#;
 385         }
 386
 387         open my $f,"-|","git-ls-tree","-r","-z",$gitrev,$srcpath;
 388         local $/ = "\0";
 389         while(<$f>) {
 390                 chomp;
 391                 my($m,$p) = split(/\t/,$_,2);
 392                 my($mode,$type,$sha1) = split(/ /,$m);
 393                 next if $type ne "blob";
 394                 if ($node_kind eq $SVN::Node::dir) {
 395                         $p = $path . substr($p,length($srcpath)-1);
 396                 } else {
 397                         $p = $path;
 398                 }
 399                 push(@$new,[$mode,$sha1,$p]);
 400         }
 401         close($f) or
 402                 print STDERR "$newrev:$newbranch: could not list files in $oldpath \@ $rev\n";
 403 }
 404
 405 sub commit {
 406         my($branch, $changed_paths, $revision, $author, $date, $message) = @_;
 407         my($author_name,$author_email,$dest);
 408         my(@old,@new);
 409
 410         if (not defined $author) {
 411                 $author_name = $author_email = "unknown";
 412         } elsif ($author =~ /^(.*?)\s+<(.*)>$/) {
 413                 ($author_name, $author_email) = ($1, $2);
 414         } else {
 415                 $author =~ s/^<(.*)>$/$1/;
 416                 $author_name = $author_email = $author;
 417         }
 418         $date = pdate($date);
 419
 420         my $tag;
 421         my $parent;
 422         if($branch eq "/") { # trunk
 423                 $parent = $opt_o;
 424         } elsif($branch =~ m#^/(.+)#) { # tag
 425                 $tag = 1;
 426                 $parent = $1;
 427         } else { # "normal" branch
 428                 # nothing to do
 429                 $parent = $branch;
 430         }
 431         $dest = $parent;
 432
 433         my $prev = $changed_paths->{"/"};
 434         if($prev and $prev->[0] eq "A") {
 435                 delete $changed_paths->{"/"};
 436                 my $oldpath = $prev->[1];
 437                 my $rev;
 438                 if(defined $oldpath) {
 439                         my $p;
 440                         ($parent,$p) = split_path($revision,$oldpath);
 441                         if($parent eq "/") {
 442                                 $parent = $opt_o;
 443                         } else {
 444                                 $parent =~ s#^/##; # if it's a tag
 445                         }
 446                 } else {
 447                         $parent = undef;
 448                 }
 449         }
 450
 451         my $rev;
 452         if($revision > $opt_s and defined $parent) {
 453                 open(H,"git-rev-parse --verify $parent |");
 454                 $rev = <H>;
 455                 close(H) or do {
 456                         print STDERR "$revision: cannot find commit '$parent'!\n";
 457                         return;
 458                 };
 459                 chop $rev;
 460                 if(length($rev) != 40) {
 461                         print STDERR "$revision: cannot find commit '$parent'!\n";
 462                         return;
 463                 }
 464                 $rev = $branches{($parent eq $opt_o) ? "/" : $parent}{"LAST"};
 465                 if($revision != $opt_s and not $rev) {
 466                         print STDERR "$revision: do not know ancestor for '$parent'!\n";
 467                         return;
 468                 }
 469         } else {
 470                 $rev = undef;
 471         }
 472
 473 #       if($prev and $prev->[0] eq "A") {
 474 #               if(not $tag) {
 475 #                       unless(open(H,"> $git_dir/refs/heads/$branch")) {
 476 #                               print STDERR "$revision: Could not create branch $branch: $!\n";
 477 #                               $state=11;
 478 #                               next;
 479 #                       }
 480 #                       print H "$rev\n"
 481 #                               or die "Could not write branch $branch: $!";
 482 #                       close(H)
 483 #                               or die "Could not write branch $branch: $!";
 484 #               }
 485 #       }
 486         if(not defined $rev) {
 487                 unlink($git_index);
 488         } elsif ($rev ne $last_rev) {
 489                 print "Switching from $last_rev to $rev ($branch)\n" if $opt_v;
 490                 system("git-read-tree", $rev);
 491                 die "read-tree failed for $rev: $?\n" if $?;
 492                 $last_rev = $rev;
 493         }
 494
 495         my $cid;
 496         if($tag and not %$changed_paths) {
 497                 $cid = $rev;
 498         } else {
 499                 my @paths = sort keys %$changed_paths;
 500                 foreach my $path(@paths) {
 501                         my $action = $changed_paths->{$path};
 502
 503                         if ($action->[0] eq "R") {
 504                                 # refer to a file/tree in an earlier commit
 505                                 push(@old,$path); # remove any old stuff
 506                         }
 507                         if(($action->[0] eq "A") || ($action->[0] eq "R")) {
 508                                 my $node_kind = node_kind($branch,$path,$revision);
 509                                 if($action->[1]) {
 510                                         copy_path($revision,$branch,$path,$action->[1],$action->[2],$node_kind,\@new);
 511                                 } elsif ($node_kind eq $SVN::Node::file) {
 512                                         my $f = get_file($revision,$branch,$path);
 513                                         if ($f) {
 514                                                 push(@new,$f) if $f;
 515                                         } else {
 516                                                 my $opath = $action->[3];
 517                                                 print STDERR "$revision: $branch: could not fetch '$opath'\n";
 518                                         }
 519                                 }
 520                         } elsif ($action->[0] eq "D") {
 521                                 push(@old,$path);
 522                         } elsif ($action->[0] eq "M") {
 523                                 my $node_kind = node_kind($branch,$path,$revision);
 524                                 if ($node_kind eq $SVN::Node::file) {
 525                                         my $f = get_file($revision,$branch,$path);
 526                                         push(@new,$f) if $f;
 527                                 }
 528                         } else {
 529                                 die "$revision: unknown action '".$action->[0]."' for $path\n";
 530                         }
 531                 }
 532
 533                 if(@old) {
 534                         open my $F, "-|", "git-ls-files", "-z", @old or die $!;
 535                         @old = ();
 536                         local $/ = "\0";
 537                         while(<$F>) {
 538                                 chomp;
 539                                 push(@old,$_);
 540                         }
 541                         close($F);
 542
 543                         while(@old) {
 544                                 my @o2;
 545                                 if(@old > 55) {
 546                                         @o2 = splice(@old,0,50);
 547                                 } else {
 548                                         @o2 = @old;
 549                                         @old = ();
 550                                 }
 551                                 system("git-update-index","--force-remove","--",@o2);
 552                                 die "Cannot remove files: $?\n" if $?;
 553                         }
 554                 }
 555                 while(@new) {
 556                         my @n2;
 557                         if(@new > 12) {
 558                                 @n2 = splice(@new,0,10);
 559                         } else {
 560                                 @n2 = @new;
 561                                 @new = ();
 562                         }
 563                         system("git-update-index","--add",
 564                                 (map { ('--cacheinfo', @$_) } @n2));
 565                         die "Cannot add files: $?\n" if $?;
 566                 }
 567
 568                 my $pid = open(C,"-|");
 569                 die "Cannot fork: $!" unless defined $pid;
 570                 unless($pid) {
 571                         exec("git-write-tree");
 572                         die "Cannot exec git-write-tree: $!\n";
 573                 }
 574                 chomp(my $tree = <C>);
 575                 length($tree) == 40
 576                         or die "Cannot get tree id ($tree): $!\n";
 577                 close(C)
 578                         or die "Error running git-write-tree: $?\n";
 579                 print "Tree ID $tree\n" if $opt_v;
 580
 581                 my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 582                 my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 583                 $pid = fork();
 584                 die "Fork: $!\n" unless defined $pid;
 585                 unless($pid) {
 586                         $pr->writer();
 587                         $pw->reader();
 588                         open(OUT,">&STDOUT");
 589                         dup2($pw->fileno(),0);
 590                         dup2($pr->fileno(),1);
 591                         $pr->close();
 592                         $pw->close();
 593
 594                         my @par = ();
 595                         @par = ("-p",$rev) if defined $rev;
 596
 597                         # loose detection of merges
 598                         # based on the commit msg
 599                         foreach my $rx (@mergerx) {
 600                                 if ($message =~ $rx) {
 601                                         my $mparent = $1;
 602                                         if ($mparent eq 'HEAD') { $mparent = $opt_o };
 603                                         if ( -e "$git_dir/refs/heads/$mparent") {
 604                                                 $mparent = get_headref($mparent, $git_dir);
 605                                                 push @par, '-p', $mparent;
 606                                                 print OUT "Merge parent branch: $mparent\n" if $opt_v;
 607                                         }
 608                                 }
 609                         }
 610
 611                         exec("env",
 612                                 "GIT_AUTHOR_NAME=$author_name",
 613                                 "GIT_AUTHOR_EMAIL=$author_email",
 614                                 "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 615                                 "GIT_COMMITTER_NAME=$author_name",
 616                                 "GIT_COMMITTER_EMAIL=$author_email",
 617                                 "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 618                                 "git-commit-tree", $tree,@par);
 619                         die "Cannot exec git-commit-tree: $!\n";
 620                 }
 621                 $pw->writer();
 622                 $pr->reader();
 623
 624                 $message =~ s/[\s\n]+\z//;
 625
 626                 print $pw "$message\n"
 627                         or die "Error writing to git-commit-tree: $!\n";
 628                 $pw->close();
 629
 630                 print "Committed change $revision:$branch ".strftime("%Y-%m-%d %H:%M:%S",gmtime($date)).")\n" if $opt_v;
 631                 chomp($cid = <$pr>);
 632                 length($cid) == 40
 633                         or die "Cannot get commit id ($cid): $!\n";
 634                 print "Commit ID $cid\n" if $opt_v;
 635                 $pr->close();
 636
 637                 waitpid($pid,0);
 638                 die "Error running git-commit-tree: $?\n" if $?;
 639         }
 640
 641         if(not defined $dest) {
 642                 print "... no known parent\n" if $opt_v;
 643         } elsif(not $tag) {
 644                 print "Writing to refs/heads/$dest\n" if $opt_v;
 645                 open(C,">$git_dir/refs/heads/$dest") and
 646                 print C ("$cid\n") and
 647                 close(C)
 648                         or die "Cannot write branch $dest for update: $!\n";
 649         }
 650
 651         if($tag) {
 652                 my($in, $out) = ('','');
 653                 $last_rev = "-" if %$changed_paths;
 654                 # the tag was 'complex', i.e. did not refer to a "real" revision
 655
 656                 $dest =~ tr/_/\./ if $opt_u;
 657
 658                 my $pid = open2($in, $out, 'git-mktag');
 659                 print $out ("object $cid\n".
 660                     "type commit\n".
 661                     "tag $dest\n".
 662                     "tagger $author_name <$author_email>\n") and
 663                 close($out)
 664                     or die "Cannot create tag object $dest: $!\n";
 665
 666                 my $tagobj = <$in>;
 667                 chomp $tagobj;
 668
 669                 if ( !close($in) or waitpid($pid, 0) != $pid or
 670                                 $? != 0 or $tagobj !~ /^[0123456789abcdef]{40}$/ ) {
 671                         die "Cannot create tag object $dest: $!\n";
 672                 }
 673
 674                 open(C,">$git_dir/refs/tags/$dest") and
 675                 print C ("$tagobj\n") and
 676                 close(C)
 677                         or die "Cannot create tag $branch: $!\n";
 678
 679                 print "Created tag '$dest' on '$branch'\n" if $opt_v;
 680         }
 681         $branches{$branch}{"LAST"} = $cid;
 682         $branches{$branch}{$revision} = $cid;
 683         $last_rev = $cid;
 684         print BRANCHES "$revision $branch $cid\n";
 685         print "DONE: $revision $dest $cid\n" if $opt_v;
 686 }
 687
 688 my ($changed_paths, $revision, $author, $date, $message, $pool) = @_;
 689 sub _commit_all {
 690         ($changed_paths, $revision, $author, $date, $message, $pool) = @_;
 691         my %p;
 692         while(my($path,$action) = each %$changed_paths) {
 693                 $p{$path} = [ $action->action,$action->copyfrom_path, $action->copyfrom_rev, $path ];
 694         }
 695         $changed_paths = \%p;
 696 }
 697
 698 sub commit_all {
 699         my %done;
 700         my @col;
 701         my $pref;
 702         my $branch;
 703
 704         while(my($path,$action) = each %$changed_paths) {
 705                 ($branch,$path) = split_path($revision,$path);
 706                 next if not defined $branch;
 707                 $done{$branch}{$path} = $action;
 708         }
 709         while(($branch,$changed_paths) = each %done) {
 710                 commit($branch, $changed_paths, $revision, $author, $date, $message);
 711         }
 712 }
 713
 714 while(++$current_rev <= $svn->{'maxrev'}) {
 715         my $pool=SVN::Pool->new;
 716         $svn->{'svn'}->get_log("/",$current_rev,$current_rev,1,1,1,\&_commit_all,$pool);
 717         $pool->clear;
 718         commit_all();
 719         if($opt_l and not --$opt_l) {
 720                 print STDERR "Stopping, because there is a memory leak (in the SVN library).\n";
 721                 print STDERR "Please repeat this command; it will continue safely\n";
 722                 last;
 723         }
 724 }
 725
 726
 727 unlink($git_index);
 728
 729 if (defined $orig_git_index) {
 730         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 731 } else {
 732         delete $ENV{GIT_INDEX_FILE};
 733 }
 734
 735 # Now switch back to the branch we were in before all of this happened
 736 if($orig_branch) {
 737         print "DONE\n" if $opt_v and (not defined $opt_l or $opt_l > 0);
 738         system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 739                 if $forward_master;
 740         unless ($opt_i) {
 741                 system('git-read-tree', '-m', '-u', 'SVN2GIT_HEAD', 'HEAD');
 742                 die "read-tree failed: $?\n" if $?;
 743         }
 744 } else {
 745         $orig_branch = "master";
 746         print "DONE; creating $orig_branch branch\n" if $opt_v and (not defined $opt_l or $opt_l > 0);
 747         system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 748                 unless -f "$git_dir/refs/heads/master";
 749         unlink("$git_dir/HEAD");
 750         symlink("refs/heads/$orig_branch","$git_dir/HEAD");
 751         unless ($opt_i) {
 752                 system('git checkout');
 753                 die "checkout failed: $?\n" if $?;
 754         }
 755 }
 756 unlink("$git_dir/SVN2GIT_HEAD");
 757 close(BRANCHES);