git-cvsimport-script

   1 #!/usr/bin/perl -w
   2
   3 # This tool is copyright (c) 2005, Matthias Urlichs.
   4 # It is released under the Gnu Public License, version 2.
   5 #
   6 # The basic idea is to aggregate CVS check-ins into related changes.
   7 # Fortunately, "cvsps" does that for us; all we have to do is to parse
   8 # its output.
   9 #
  10 # Checking out the files is done by a single long-running CVS connection
  11 # / server process.
  12 #
  13 # The head revision is on branch "origin" by default.
  14 # You can change that with the '-o' option.
  15
  16 use strict;
  17 use warnings;
  18 use Getopt::Std;
  19 use File::Spec;
  20 use File::Temp qw(tempfile);
  21 use File::Path qw(mkpath);
  22 use File::Basename qw(basename dirname);
  23 use Time::Local;
  24 use IO::Socket;
  25 use IO::Pipe;
  26 use POSIX qw(strftime dup2);
  27
  28 $SIG{'PIPE'}="IGNORE";
  29 $ENV{'TZ'}="UTC";
  30
  31 our($opt_h,$opt_o,$opt_v,$opt_d,$opt_p,$opt_C,$opt_z,$opt_i);
  32
  33 sub usage() {
  34         print STDERR <<END;
  35 Usage: ${\basename $0}     # fetch/update GIT from CVS
  36        [ -o branch-for-HEAD ] [ -h ] [ -v ] [ -d CVSROOT ]
  37        [ -p opts-for-cvsps ] [ -C GIT_repository ] [ -z fuzz ]
  38        [ -i ] [ CVS_module ]
  39 END
  40         exit(1);
  41 }
  42
  43 getopts("hivo:d:p:C:z:") or usage();
  44 usage if $opt_h;
  45
  46 @ARGV <= 1 or usage();
  47
  48 if($opt_d) {
  49         $ENV{"CVSROOT"} = $opt_d;
  50 } elsif(-f 'CVS/Root') {
  51         open my $f, '<', 'CVS/Root' or die 'Failed to open CVS/Root';
  52         $opt_d = <$f>;
  53         chomp $opt_d;
  54         close $f;
  55         $ENV{"CVSROOT"} = $opt_d;
  56 } elsif($ENV{"CVSROOT"}) {
  57         $opt_d = $ENV{"CVSROOT"};
  58 } else {
  59         die "CVSROOT needs to be set";
  60 }
  61 $opt_o ||= "origin";
  62 my $git_tree = $opt_C;
  63 $git_tree ||= ".";
  64
  65 my $cvs_tree;
  66 if ($#ARGV == 0) {
  67         $cvs_tree = $ARGV[0];
  68 } elsif (-f 'CVS/Repository') {
  69         open my $f, '<', 'CVS/Repository' or
  70             die 'Failed to open CVS/Repository';
  71         $cvs_tree = <$f>;
  72         chomp $cvs_tree;
  73         close $f
  74 } else {
  75         usage();
  76 }
  77
  78 select(STDERR); $|=1; select(STDOUT);
  79
  80
  81 package CVSconn;
  82 # Basic CVS dialog.
  83 # We're only interested in connecting and downloading, so ...
  84
  85 use File::Spec;
  86 use File::Temp qw(tempfile);
  87 use POSIX qw(strftime dup2);
  88
  89 sub new {
  90         my($what,$repo,$subdir) = @_;
  91         $what=ref($what) if ref($what);
  92
  93         my $self = {};
  94         $self->{'buffer'} = "";
  95         bless($self,$what);
  96
  97         $repo =~ s#/+$##;
  98         $self->{'fullrep'} = $repo;
  99         $self->conn();
 100
 101         $self->{'subdir'} = $subdir;
 102         $self->{'lines'} = undef;
 103
 104         return $self;
 105 }
 106
 107 sub conn {
 108         my $self = shift;
 109         my $repo = $self->{'fullrep'};
 110         if($repo =~ s/^:pserver:(?:(.*?)(?::(.*?))?@)?([^:\/]*)(?::(\d*))?//) {
 111                 my($user,$pass,$serv,$port) = ($1,$2,$3,$4);
 112                 $user="anonymous" unless defined $user;
 113                 my $rr2 = "-";
 114                 unless($port) {
 115                         $rr2 = ":pserver:$user\@$serv:$repo";
 116                         $port=2401;
 117                 }
 118                 my $rr = ":pserver:$user\@$serv:$port$repo";
 119
 120                 unless($pass) {
 121                         open(H,$ENV{'HOME'}."/.cvspass") and do {
 122                                 # :pserver:cvs@mea.tmt.tele.fi:/cvsroot/zmailer Ah<Z
 123                                 while(<H>) {
 124                                         chomp;
 125                                         s/^\/\d+\s+//;
 126                                         my ($w,$p) = split(/\s/,$_,2);
 127                                         if($w eq $rr or $w eq $rr2) {
 128                                                 $pass = $p;
 129                                                 last;
 130                                         }
 131                                 }
 132                         };
 133                 }
 134                 $pass="A" unless $pass;
 135
 136                 my $s = IO::Socket::INET->new(PeerHost => $serv, PeerPort => $port);
 137                 die "Socket to $serv: $!\n" unless defined $s;
 138                 $s->write("BEGIN AUTH REQUEST\n$repo\n$user\n$pass\nEND AUTH REQUEST\n")
 139                         or die "Write to $serv: $!\n";
 140                 $s->flush();
 141
 142                 my $rep = <$s>;
 143
 144                 if($rep ne "I LOVE YOU\n") {
 145                         $rep="<unknown>" unless $rep;
 146                         die "AuthReply: $rep\n";
 147                 }
 148                 $self->{'socketo'} = $s;
 149                 $self->{'socketi'} = $s;
 150         } else { # local or ext: Fork off our own cvs server.
 151                 my $pr = IO::Pipe->new();
 152                 my $pw = IO::Pipe->new();
 153                 my $pid = fork();
 154                 die "Fork: $!\n" unless defined $pid;
 155                 my $cvs = 'cvs';
 156                 $cvs = $ENV{CVS_SERVER} if exists $ENV{CVS_SERVER};
 157                 my $rsh = 'rsh';
 158                 $rsh = $ENV{CVS_RSH} if exists $ENV{CVS_RSH};
 159
 160                 my @cvs = ($cvs, 'server');
 161                 my ($local, $user, $host);
 162                 $local = $repo =~ s/:local://;
 163                 if (!$local) {
 164                     $repo =~ s/:ext://;
 165                     $local = !($repo =~ s/^(?:([^\@:]+)\@)?([^:]+)://);
 166                     ($user, $host) = ($1, $2);
 167                 }
 168                 if (!$local) {
 169                     if ($user) {
 170                         unshift @cvs, $rsh, '-l', $user, $host;
 171                     } else {
 172                         unshift @cvs, $rsh, $host;
 173                     }
 174                 }
 175
 176                 unless($pid) {
 177                         $pr->writer();
 178                         $pw->reader();
 179                         dup2($pw->fileno(),0);
 180                         dup2($pr->fileno(),1);
 181                         $pr->close();
 182                         $pw->close();
 183                         exec(@cvs);
 184                 }
 185                 $pw->writer();
 186                 $pr->reader();
 187                 $self->{'socketo'} = $pw;
 188                 $self->{'socketi'} = $pr;
 189         }
 190         $self->{'socketo'}->write("Root $repo\n");
 191
 192         # Trial and error says that this probably is the minimum set
 193         $self->{'socketo'}->write("Valid-responses ok error Valid-requests Mode M Mbinary E F Checked-in Created Updated Merged Removed\n");
 194
 195         $self->{'socketo'}->write("valid-requests\n");
 196         $self->{'socketo'}->flush();
 197
 198         chomp(my $rep=$self->readline());
 199         if($rep !~ s/^Valid-requests\s*//) {
 200                 $rep="<unknown>" unless $rep;
 201                 die "Expected Valid-requests from server, but got: $rep\n";
 202         }
 203         chomp(my $res=$self->readline());
 204         die "validReply: $res\n" if $res ne "ok";
 205
 206         $self->{'socketo'}->write("UseUnchanged\n") if $rep =~ /\bUseUnchanged\b/;
 207         $self->{'repo'} = $repo;
 208 }
 209
 210 sub readline {
 211         my($self) = @_;
 212         return $self->{'socketi'}->getline();
 213 }
 214
 215 sub _file {
 216         # Request a file with a given revision.
 217         # Trial and error says this is a good way to do it. :-/
 218         my($self,$fn,$rev) = @_;
 219         $self->{'socketo'}->write("Argument -N\n") or return undef;
 220         $self->{'socketo'}->write("Argument -P\n") or return undef;
 221         # $self->{'socketo'}->write("Argument -ko\n") or return undef;
 222         # -ko: Linus' version doesn't use it
 223         $self->{'socketo'}->write("Argument -r\n") or return undef;
 224         $self->{'socketo'}->write("Argument $rev\n") or return undef;
 225         $self->{'socketo'}->write("Argument --\n") or return undef;
 226         $self->{'socketo'}->write("Argument $self->{'subdir'}/$fn\n") or return undef;
 227         $self->{'socketo'}->write("Directory .\n") or return undef;
 228         $self->{'socketo'}->write("$self->{'repo'}\n") or return undef;
 229         # $self->{'socketo'}->write("Sticky T1.0\n") or return undef;
 230         $self->{'socketo'}->write("co\n") or return undef;
 231         $self->{'socketo'}->flush() or return undef;
 232         $self->{'lines'} = 0;
 233         return 1;
 234 }
 235 sub _line {
 236         # Read a line from the server.
 237         # ... except that 'line' may be an entire file. ;-)
 238         my($self, $fh) = @_;
 239         die "Not in lines" unless defined $self->{'lines'};
 240
 241         my $line;
 242         my $res=0;
 243         while(defined($line = $self->readline())) {
 244                 # M U gnupg-cvs-rep/AUTHORS
 245                 # Updated gnupg-cvs-rep/
 246                 # /daten/src/rsync/gnupg-cvs-rep/AUTHORS
 247                 # /AUTHORS/1.1///T1.1
 248                 # u=rw,g=rw,o=rw
 249                 # 0
 250                 # ok
 251
 252                 if($line =~ s/^(?:Created|Updated) //) {
 253                         $line = $self->readline(); # path
 254                         $line = $self->readline(); # Entries line
 255                         my $mode = $self->readline(); chomp $mode;
 256                         $self->{'mode'} = $mode;
 257                         defined (my $cnt = $self->readline())
 258                                 or die "EOF from server after 'Changed'\n";
 259                         chomp $cnt;
 260                         die "Duh: Filesize $cnt" if $cnt !~ /^\d+$/;
 261                         $line="";
 262                         $res=0;
 263                         while($cnt) {
 264                                 my $buf;
 265                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 266                                 die "Server: Filesize $cnt: $num: $!\n" if not defined $num or $num<=0;
 267                                 print $fh $buf;
 268                                 $res += $num;
 269                                 $cnt -= $num;
 270                         }
 271                 } elsif($line =~ s/^ //) {
 272                         print $fh $line;
 273                         $res += length($line);
 274                 } elsif($line =~ /^M\b/) {
 275                         # output, do nothing
 276                 } elsif($line =~ /^Mbinary\b/) {
 277                         my $cnt;
 278                         die "EOF from server after 'Mbinary'" unless defined ($cnt = $self->readline());
 279                         chomp $cnt;
 280                         die "Duh: Mbinary $cnt" if $cnt !~ /^\d+$/ or $cnt<1;
 281                         $line="";
 282                         while($cnt) {
 283                                 my $buf;
 284                                 my $num = $self->{'socketi'}->read($buf,$cnt);
 285                                 die "S: Mbinary $cnt: $num: $!\n" if not defined $num or $num<=0;
 286                                 print $fh $buf;
 287                                 $res += $num;
 288                                 $cnt -= $num;
 289                         }
 290                 } else {
 291                         chomp $line;
 292                         if($line eq "ok") {
 293                                 # print STDERR "S: ok (".length($res).")\n";
 294                                 return $res;
 295                         } elsif($line =~ s/^E //) {
 296                                 # print STDERR "S: $line\n";
 297                         } elsif($line =~ /^Remove-entry /i) {
 298                                 $line = $self->readline(); # filename
 299                                 $line = $self->readline(); # OK
 300                                 chomp $line;
 301                                 die "Unknown: $line" if $line ne "ok";
 302                                 return -1;
 303                         } else {
 304                                 die "Unknown: $line\n";
 305                         }
 306                 }
 307         }
 308 }
 309 sub file {
 310         my($self,$fn,$rev) = @_;
 311         my $res;
 312
 313         my ($fh, $name) = tempfile('gitcvs.XXXXXX',
 314                     DIR => File::Spec->tmpdir(), UNLINK => 1);
 315
 316         $self->_file($fn,$rev) and $res = $self->_line($fh);
 317
 318         if (!defined $res) {
 319             # retry
 320             $self->conn();
 321             $self->_file($fn,$rev)
 322                     or die "No file command send\n";
 323             $res = $self->_line($fh);
 324             die "No input: $fn $rev\n" unless defined $res;
 325         }
 326         close ($fh);
 327
 328         return ($name, $res);
 329 }
 330
 331
 332 package main;
 333
 334 my $cvs = CVSconn->new($opt_d, $cvs_tree);
 335
 336
 337 sub pdate($) {
 338         my($d) = @_;
 339         m#(\d{2,4})/(\d\d)/(\d\d)\s(\d\d):(\d\d)(?::(\d\d))?#
 340                 or die "Unparseable date: $d\n";
 341         my $y=$1; $y-=1900 if $y>1900;
 342         return timegm($6||0,$5,$4,$3,$2-1,$y);
 343 }
 344
 345 sub pmode($) {
 346         my($mode) = @_;
 347         my $m = 0;
 348         my $mm = 0;
 349         my $um = 0;
 350         for my $x(split(//,$mode)) {
 351                 if($x eq ",") {
 352                         $m |= $mm&$um;
 353                         $mm = 0;
 354                         $um = 0;
 355                 } elsif($x eq "u") { $um |= 0700;
 356                 } elsif($x eq "g") { $um |= 0070;
 357                 } elsif($x eq "o") { $um |= 0007;
 358                 } elsif($x eq "r") { $mm |= 0444;
 359                 } elsif($x eq "w") { $mm |= 0222;
 360                 } elsif($x eq "x") { $mm |= 0111;
 361                 } elsif($x eq "=") { # do nothing
 362                 } else { die "Unknown mode: $mode\n";
 363                 }
 364         }
 365         $m |= $mm&$um;
 366         return $m;
 367 }
 368
 369 sub getwd() {
 370         my $pwd = `pwd`;
 371         chomp $pwd;
 372         return $pwd;
 373 }
 374
 375 -d $git_tree
 376         or mkdir($git_tree,0777)
 377         or die "Could not create $git_tree: $!";
 378 chdir($git_tree);
 379
 380 my $last_branch = "";
 381 my $orig_branch = "";
 382 my $forward_master = 0;
 383 my %branch_date;
 384
 385 my $git_dir = $ENV{"GIT_DIR"} || ".git";
 386 $git_dir = getwd()."/".$git_dir unless $git_dir =~ m#^/#;
 387 $ENV{"GIT_DIR"} = $git_dir;
 388 my $orig_git_index;
 389 $orig_git_index = $ENV{GIT_INDEX_FILE} if exists $ENV{GIT_INDEX_FILE};
 390 my ($git_ih, $git_index) = tempfile('gitXXXXXX', SUFFIX => '.idx',
 391                                     DIR => File::Spec->tmpdir());
 392 close ($git_ih);
 393 $ENV{GIT_INDEX_FILE} = $git_index;
 394 unless(-d $git_dir) {
 395         system("git-init-db");
 396         die "Cannot init the GIT db at $git_tree: $?\n" if $?;
 397         system("git-read-tree");
 398         die "Cannot init an empty tree: $?\n" if $?;
 399
 400         $last_branch = $opt_o;
 401         $orig_branch = "";
 402 } else {
 403         -f "$git_dir/refs/heads/$opt_o"
 404                 or die "Branch '$opt_o' does not exist.\n".
 405                        "Either use the correct '-o branch' option,\n".
 406                        "or import to a new repository.\n";
 407
 408         $last_branch = basename(readlink("$git_dir/HEAD"));
 409         unless($last_branch) {
 410                 warn "Cannot read the last branch name: $! -- assuming 'master'\n";
 411                 $last_branch = "master";
 412         }
 413         $orig_branch = $last_branch;
 414         if (-f "$git_dir/CVS2GIT_HEAD") {
 415                 die <<EOM;
 416 CVS2GIT_HEAD exists.
 417 Make sure your working directory corresponds to HEAD and remove CVS2GIT_HEAD.
 418 You may need to run
 419
 420     git-read-tree -m -u CVS2GIT_HEAD HEAD
 421 EOM
 422         }
 423         system('cp', "$git_dir/HEAD", "$git_dir/CVS2GIT_HEAD");
 424
 425         $forward_master =
 426             $opt_o ne 'master' && -f "$git_dir/refs/heads/master" &&
 427             system('cmp', '-s', "$git_dir/refs/heads/master",
 428                                 "$git_dir/refs/heads/$opt_o") == 0;
 429
 430         # populate index
 431         system('git-read-tree', $last_branch);
 432         die "read-tree failed: $?\n" if $?;
 433
 434         # Get the last import timestamps
 435         opendir(D,"$git_dir/refs/heads");
 436         while(defined(my $head = readdir(D))) {
 437                 next if $head =~ /^\./;
 438                 open(F,"$git_dir/refs/heads/$head")
 439                         or die "Bad head branch: $head: $!\n";
 440                 chomp(my $ftag = <F>);
 441                 close(F);
 442                 open(F,"git-cat-file commit $ftag |");
 443                 while(<F>) {
 444                         next unless /^author\s.*\s(\d+)\s[-+]\d{4}$/;
 445                         $branch_date{$head} = $1;
 446                         last;
 447                 }
 448                 close(F);
 449         }
 450         closedir(D);
 451 }
 452
 453 -d $git_dir
 454         or die "Could not create git subdir ($git_dir).\n";
 455
 456 my $pid = open(CVS,"-|");
 457 die "Cannot fork: $!\n" unless defined $pid;
 458 unless($pid) {
 459         my @opt;
 460         @opt = split(/,/,$opt_p) if defined $opt_p;
 461         unshift @opt, '-z', $opt_z if defined $opt_z;
 462         exec("cvsps",@opt,"-u","-A","--cvs-direct",'--root',$opt_d,$cvs_tree);
 463         die "Could not start cvsps: $!\n";
 464 }
 465
 466
 467 ## cvsps output:
 468 #---------------------
 469 #PatchSet 314
 470 #Date: 1999/09/18 13:03:59
 471 #Author: wkoch
 472 #Branch: STABLE-BRANCH-1-0
 473 #Ancestor branch: HEAD
 474 #Tag: (none)
 475 #Log:
 476 #    See ChangeLog: Sat Sep 18 13:03:28 CEST 1999  Werner Koch
 477 #Members:
 478 #       README:1.57->1.57.2.1
 479 #       VERSION:1.96->1.96.2.1
 480 #
 481 #---------------------
 482
 483 my $state = 0;
 484
 485 my($patchset,$date,$author,$branch,$ancestor,$tag,$logmsg);
 486 my(@old,@new);
 487 my $commit = sub {
 488         my $pid;
 489         while(@old) {
 490                 my @o2;
 491                 if(@old > 55) {
 492                         @o2 = splice(@old,0,50);
 493                 } else {
 494                         @o2 = @old;
 495                         @old = ();
 496                 }
 497                 system("git-update-cache","--force-remove","--",@o2);
 498                 die "Cannot remove files: $?\n" if $?;
 499         }
 500         while(@new) {
 501                 my @n2;
 502                 if(@new > 12) {
 503                         @n2 = splice(@new,0,10);
 504                 } else {
 505                         @n2 = @new;
 506                         @new = ();
 507                 }
 508                 system("git-update-cache","--add",
 509                         (map { ('--cacheinfo', @$_) } @n2));
 510                 die "Cannot add files: $?\n" if $?;
 511         }
 512
 513         $pid = open(C,"-|");
 514         die "Cannot fork: $!" unless defined $pid;
 515         unless($pid) {
 516                 exec("git-write-tree");
 517                 die "Cannot exec git-write-tree: $!\n";
 518         }
 519         chomp(my $tree = <C>);
 520         length($tree) == 40
 521                 or die "Cannot get tree id ($tree): $!\n";
 522         close(C)
 523                 or die "Error running git-write-tree: $?\n";
 524         print "Tree ID $tree\n" if $opt_v;
 525
 526         my $parent = "";
 527         if(open(C,"$git_dir/refs/heads/$last_branch")) {
 528                 chomp($parent = <C>);
 529                 close(C);
 530                 length($parent) == 40
 531                         or die "Cannot get parent id ($parent): $!\n";
 532                 print "Parent ID $parent\n" if $opt_v;
 533         }
 534
 535         my $pr = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 536         my $pw = IO::Pipe->new() or die "Cannot open pipe: $!\n";
 537         $pid = fork();
 538         die "Fork: $!\n" unless defined $pid;
 539         unless($pid) {
 540                 $pr->writer();
 541                 $pw->reader();
 542                 dup2($pw->fileno(),0);
 543                 dup2($pr->fileno(),1);
 544                 $pr->close();
 545                 $pw->close();
 546
 547                 my @par = ();
 548                 @par = ("-p",$parent) if $parent;
 549                 exec("env",
 550                         "GIT_AUTHOR_NAME=$author",
 551                         "GIT_AUTHOR_EMAIL=$author",
 552                         "GIT_AUTHOR_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 553                         "GIT_COMMITTER_NAME=$author",
 554                         "GIT_COMMITTER_EMAIL=$author",
 555                         "GIT_COMMITTER_DATE=".strftime("+0000 %Y-%m-%d %H:%M:%S",gmtime($date)),
 556                         "git-commit-tree", $tree,@par);
 557                 die "Cannot exec git-commit-tree: $!\n";
 558         }
 559         $pw->writer();
 560         $pr->reader();
 561
 562         # compatibility with git2cvs
 563         substr($logmsg,32767) = "" if length($logmsg) > 32767;
 564         $logmsg =~ s/[\s\n]+\z//;
 565
 566         print $pw "$logmsg\n"
 567                 or die "Error writing to git-commit-tree: $!\n";
 568         $pw->close();
 569
 570         print "Committed patch $patchset ($branch ".strftime("%Y-%m-%d %H:%M:%S",gmtime($date)).")\n" if $opt_v;
 571         chomp(my $cid = <$pr>);
 572         length($cid) == 40
 573                 or die "Cannot get commit id ($cid): $!\n";
 574         print "Commit ID $cid\n" if $opt_v;
 575         $pr->close();
 576
 577         waitpid($pid,0);
 578         die "Error running git-commit-tree: $?\n" if $?;
 579
 580         open(C,">$git_dir/refs/heads/$branch")
 581                 or die "Cannot open branch $branch for update: $!\n";
 582         print C "$cid\n"
 583                 or die "Cannot write branch $branch for update: $!\n";
 584         close(C)
 585                 or die "Cannot write branch $branch for update: $!\n";
 586
 587         if($tag) {
 588                 open(C,">$git_dir/refs/tags/$tag")
 589                         or die "Cannot create tag $tag: $!\n";
 590                 print C "$cid\n"
 591                         or die "Cannot write tag $branch: $!\n";
 592                 close(C)
 593                         or die "Cannot write tag $branch: $!\n";
 594                 print "Created tag '$tag' on '$branch'\n" if $opt_v;
 595         }
 596 };
 597
 598 while(<CVS>) {
 599         chomp;
 600         if($state == 0 and /^-+$/) {
 601                 $state = 1;
 602         } elsif($state == 0) {
 603                 $state = 1;
 604                 redo;
 605         } elsif(($state==0 or $state==1) and s/^PatchSet\s+//) {
 606                 $patchset = 0+$_;
 607                 $state=2;
 608         } elsif($state == 2 and s/^Date:\s+//) {
 609                 $date = pdate($_);
 610                 unless($date) {
 611                         print STDERR "Could not parse date: $_\n";
 612                         $state=0;
 613                         next;
 614                 }
 615                 $state=3;
 616         } elsif($state == 3 and s/^Author:\s+//) {
 617                 s/\s+$//;
 618                 $author = $_;
 619                 $state = 4;
 620         } elsif($state == 4 and s/^Branch:\s+//) {
 621                 s/\s+$//;
 622                 $branch = $_;
 623                 $state = 5;
 624         } elsif($state == 5 and s/^Ancestor branch:\s+//) {
 625                 s/\s+$//;
 626                 $ancestor = $_;
 627                 $ancestor = $opt_o if $ancestor eq "HEAD";
 628                 $state = 6;
 629         } elsif($state == 5) {
 630                 $ancestor = undef;
 631                 $state = 6;
 632                 redo;
 633         } elsif($state == 6 and s/^Tag:\s+//) {
 634                 s/\s+$//;
 635                 if($_ eq "(none)") {
 636                         $tag = undef;
 637                 } else {
 638                         $tag = $_;
 639                 }
 640                 $state = 7;
 641         } elsif($state == 7 and /^Log:/) {
 642                 $logmsg = "";
 643                 $state = 8;
 644         } elsif($state == 8 and /^Members:/) {
 645                 $branch = $opt_o if $branch eq "HEAD";
 646                 if(defined $branch_date{$branch} and $branch_date{$branch} >= $date) {
 647                         # skip
 648                         print "skip patchset $patchset: $date before $branch_date{$branch}\n" if $opt_v;
 649                         $state = 11;
 650                         next;
 651                 }
 652                 if($ancestor) {
 653                         if(-f "$git_dir/refs/heads/$branch") {
 654                                 print STDERR "Branch $branch already exists!\n";
 655                                 $state=11;
 656                                 next;
 657                         }
 658                         unless(open(H,"$git_dir/refs/heads/$ancestor")) {
 659                                 print STDERR "Branch $ancestor does not exist!\n";
 660                                 $state=11;
 661                                 next;
 662                         }
 663                         chomp(my $id = <H>);
 664                         close(H);
 665                         unless(open(H,"> $git_dir/refs/heads/$branch")) {
 666                                 print STDERR "Could not create branch $branch: $!\n";
 667                                 $state=11;
 668                                 next;
 669                         }
 670                         print H "$id\n"
 671                                 or die "Could not write branch $branch: $!";
 672                         close(H)
 673                                 or die "Could not write branch $branch: $!";
 674                 }
 675                 if(($ancestor || $branch) ne $last_branch) {
 676                         print "Switching from $last_branch to $branch\n" if $opt_v;
 677                         system("git-read-tree", $branch);
 678                         die "read-tree failed: $?\n" if $?;
 679                 }
 680                 $last_branch = $branch if $branch ne $last_branch;
 681                 $state = 9;
 682         } elsif($state == 8) {
 683                 $logmsg .= "$_\n";
 684         } elsif($state == 9 and /^\s+(.+?):(INITIAL|\d+(?:\.\d+)+)->(\d+(?:\.\d+)+)\s*$/) {
 685 #       VERSION:1.96->1.96.2.1
 686                 my $init = ($2 eq "INITIAL");
 687                 my $fn = $1;
 688                 my $rev = $3;
 689                 $fn =~ s#^/+##;
 690                 my ($tmpname, $size) = $cvs->file($fn,$rev);
 691                 if($size == -1) {
 692                         push(@old,$fn);
 693                         print "Drop $fn\n" if $opt_v;
 694                 } else {
 695                         print "".($init ? "New" : "Update")." $fn: $size bytes\n" if $opt_v;
 696                         open my $F, '-|', "git-hash-object -w $tmpname"
 697                                 or die "Cannot create object: $!\n";
 698                         my $sha = <$F>;
 699                         chomp $sha;
 700                         close $F;
 701                         my $mode = pmode($cvs->{'mode'});
 702                         push(@new,[$mode, $sha, $fn]); # may be resurrected!
 703                 }
 704                 unlink($tmpname);
 705         } elsif($state == 9 and /^\s+(.+?):\d(?:\.\d+)+->(\d(?:\.\d+)+)\(DEAD\)\s*$/) {
 706                 my $fn = $1;
 707                 $fn =~ s#^/+##;
 708                 push(@old,$fn);
 709                 print "Delete $fn\n" if $opt_v;
 710         } elsif($state == 9 and /^\s*$/) {
 711                 $state = 10;
 712         } elsif(($state == 9 or $state == 10) and /^-+$/) {
 713                 &$commit();
 714                 $state = 1;
 715         } elsif($state == 11 and /^-+$/) {
 716                 $state = 1;
 717         } elsif(/^-+$/) { # end of unknown-line processing
 718                 $state = 1;
 719         } elsif($state != 11) { # ignore stuff when skipping
 720                 print "* UNKNOWN LINE * $_\n";
 721         }
 722 }
 723 &$commit() if $branch and $state != 11;
 724
 725 unlink($git_index);
 726
 727 if (defined $orig_git_index) {
 728         $ENV{GIT_INDEX_FILE} = $orig_git_index;
 729 } else {
 730         delete $ENV{GIT_INDEX_FILE};
 731 }
 732
 733 # Now switch back to the branch we were in before all of this happened
 734 if($orig_branch) {
 735         print "DONE\n" if $opt_v;
 736         system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 737                 if $forward_master;
 738         unless ($opt_i) {
 739                 system('git-read-tree', '-m', '-u', 'CVS2GIT_HEAD', 'HEAD');
 740                 die "read-tree failed: $?\n" if $?;
 741         }
 742 } else {
 743         $orig_branch = "master";
 744         print "DONE; creating $orig_branch branch\n" if $opt_v;
 745         system("cp","$git_dir/refs/heads/$opt_o","$git_dir/refs/heads/master")
 746                 unless -f "$git_dir/refs/heads/master";
 747         unlink("$git_dir/HEAD");
 748         symlink("refs/heads/$orig_branch","$git_dir/HEAD");
 749         unless ($opt_i) {
 750                 system('git checkout');
 751                 die "checkout failed: $?\n" if $?;
 752         }
 753 }
 754 unlink("$git_dir/CVS2GIT_HEAD");