configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(collectd, m4_esyscmd(./version-gen.sh))
   3 AC_CONFIG_SRCDIR(src/collectd.c)
   4 AC_CONFIG_HEADERS(src/config.h)
   5 AM_INIT_AUTOMAKE(dist-bzip2)
   6 AC_LANG(C)
   7
   8 AC_PREFIX_DEFAULT("/opt/collectd")
   9
  10 AC_SYS_LARGEFILE
  11
  12 #
  13 # Checks for programs.
  14 #
  15 AC_PROG_CC
  16 AC_PROG_CPP
  17 AC_PROG_INSTALL
  18 AC_PROG_LN_S
  19 AC_PROG_MAKE_SET
  20 AM_CONDITIONAL(COMPILER_IS_GCC, test "x$GCC" = "xyes")
  21
  22 dnl configure libtool
  23 AC_DISABLE_STATIC
  24 AC_LIBLTDL_CONVENIENCE
  25 AC_SUBST(LTDLINCL)
  26 AC_SUBST(LIBLTDL)
  27 AC_LIBTOOL_DLOPEN
  28 AC_PROG_LIBTOOL
  29 AC_PROG_LEX
  30 AC_PROG_YACC
  31 AC_CONFIG_SUBDIRS(libltdl)
  32
  33 AC_MSG_CHECKING([for kernel type ($host_os)])
  34 case $host_os in
  35         *linux*)
  36         AC_DEFINE([KERNEL_LINUX], 1, [True if program is to be compiled for a Linux kernel])
  37         ac_system="Linux"
  38         ;;
  39         *solaris*)
  40         AC_DEFINE([KERNEL_SOLARIS], 1, [True if program is to be compiled for a Solaris kernel])
  41         ac_system="Solaris"
  42         ;;
  43         *darwin*)
  44         ac_system="Darwin"
  45         ;;
  46         *)
  47         ac_system="unknown"
  48 esac
  49 AC_MSG_RESULT([$ac_system])
  50
  51 #
  52 # Checks for header files.
  53 #
  54 AC_HEADER_STDC
  55 AC_HEADER_SYS_WAIT
  56 AC_HEADER_DIRENT
  57
  58 AC_CHECK_HEADERS(stdint.h stdio.h errno.h math.h stdarg.h syslog.h fcntl.h signal.h assert.h sys/types.h sys/socket.h sys/select.h poll.h netdb.h arpa/inet.h sys/resource.h sys/param.h kstat.h regex.h sys/ioctl.h)
  59
  60 # For ping library
  61 AC_CHECK_HEADERS(netinet/in_systm.h, [], [],
  62 [#if HAVE_STDINT_H
  63 # include <stdint.h>
  64 #endif
  65 #if HAVE_SYS_TYPES_H
  66 # include <sys/types.h>
  67 #endif
  68 ])
  69 AC_CHECK_HEADERS(netinet/in.h, [], [],
  70 [#if HAVE_STDINT_H
  71 # include <stdint.h>
  72 #endif
  73 #if HAVE_SYS_TYPES_H
  74 # include <sys/types.h>
  75 #endif
  76 #if HAVE_NETINET_IN_SYSTM_H
  77 # include <netinet/in_systm.h>
  78 #endif
  79 ])
  80 AC_CHECK_HEADERS(netinet/ip.h, [], [],
  81 [#if HAVE_STDINT_H
  82 # include <stdint.h>
  83 #endif
  84 #if HAVE_SYS_TYPES_H
  85 # include <sys/types.h>
  86 #endif
  87 #if HAVE_NETINET_IN_SYSTM_H
  88 # include <netinet/in_systm.h>
  89 #endif
  90 #if HAVE_NETINET_IN_H
  91 # include <netinet/in.h>
  92 #endif
  93 ])
  94 AC_CHECK_HEADERS(netinet/ip_icmp.h, [], [],
  95 [#if HAVE_STDINT_H
  96 # include <stdint.h>
  97 #endif
  98 #if HAVE_SYS_TYPES_H
  99 # include <sys/types.h>
 100 #endif
 101 #if HAVE_NETINET_IN_SYSTM_H
 102 # include <netinet/in_systm.h>
 103 #endif
 104 #if HAVE_NETINET_IN_H
 105 # include <netinet/in.h>
 106 #endif
 107 #if HAVE_NETINET_IP_H
 108 # include <netinet/ip.h>
 109 #endif
 110 ])
 111 AC_CHECK_HEADERS(netinet/ip_var.h, [], [],
 112 [#if HAVE_STDINT_H
 113 # include <stdint.h>
 114 #endif
 115 #if HAVE_SYS_TYPES_H
 116 # include <sys/types.h>
 117 #endif
 118 #if HAVE_NETINET_IN_SYSTM_H
 119 # include <netinet/in_systm.h>
 120 #endif
 121 #if HAVE_NETINET_IN_H
 122 # include <netinet/in.h>
 123 #endif
 124 #if HAVE_NETINET_IP_H
 125 # include <netinet/ip.h>
 126 #endif
 127 ])
 128 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
 129 [#if HAVE_STDINT_H
 130 # include <stdint.h>
 131 #endif
 132 #if HAVE_SYS_TYPES_H
 133 # include <sys/types.h>
 134 #endif
 135 #if HAVE_NETINET_IN_SYSTM_H
 136 # include <netinet/in_systm.h>
 137 #endif
 138 #if HAVE_NETINET_IN_H
 139 # include <netinet/in.h>
 140 #endif
 141 ])
 142 AC_CHECK_HEADERS(netinet/icmp6.h, [], [],
 143 [#if HAVE_STDINT_H
 144 # include <stdint.h>
 145 #endif
 146 #if HAVE_SYS_TYPES_H
 147 # include <sys/types.h>
 148 #endif
 149 #if HAVE_NETINET_IN_SYSTM_H
 150 # include <netinet/in_systm.h>
 151 #endif
 152 #if HAVE_NETINET_IN_H
 153 # include <netinet/in.h>
 154 #endif
 155 #if HAVE_NETINET_IP6_H
 156 # include <netinet/ip6.h>
 157 #endif
 158 ])
 159 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 160 [#if HAVE_STDINT_H
 161 # include <stdint.h>
 162 #endif
 163 #if HAVE_SYS_TYPES_H
 164 # include <sys/types.h>
 165 #endif
 166 #if HAVE_NETINET_IN_SYSTM_H
 167 # include <netinet/in_systm.h>
 168 #endif
 169 #if HAVE_NETINET_IN_H
 170 # include <netinet/in.h>
 171 #endif
 172 #if HAVE_NETINET_IP_H
 173 # include <netinet/ip.h>
 174 #endif
 175 ])
 176 AC_CHECK_HEADERS(netinet/udp.h, [], [],
 177 [#if HAVE_STDINT_H
 178 # include <stdint.h>
 179 #endif
 180 #if HAVE_SYS_TYPES_H
 181 # include <sys/types.h>
 182 #endif
 183 #if HAVE_NETINET_IN_SYSTM_H
 184 # include <netinet/in_systm.h>
 185 #endif
 186 #if HAVE_NETINET_IN_H
 187 # include <netinet/in.h>
 188 #endif
 189 #if HAVE_NETINET_IP_H
 190 # include <netinet/ip.h>
 191 #endif
 192 ])
 193
 194 # For cpu modules
 195 AC_CHECK_HEADERS(sys/dkstat.h)
 196 if test "x$ac_system" = "xDarwin"
 197 then
 198         AC_CHECK_HEADERS(mach/mach_init.h mach/host_priv.h mach/mach_error.h mach/mach_host.h mach/mach_port.h mach/mach_types.h mach/message.h mach/processor_set.h mach/processor.h mach/processor_info.h mach/task.h mach/thread_act.h mach/vm_region.h mach/vm_map.h mach/vm_prot.h mach/vm_statistics.h mach/kern_return.h)
 199         AC_CHECK_HEADERS(CoreFoundation/CoreFoundation.h IOKit/IOKitLib.h IOKit/IOTypes.h IOKit/ps/IOPSKeys.h IOKit/IOBSD.h IOKit/storage/IOBlockStorageDriver.h)
 200 fi
 201 AC_CHECK_HEADERS(sys/sysctl.h, [], [],
 202 [
 203 #if HAVE_SYS_TYPES_H
 204 #  include <sys/types.h>
 205 #endif
 206 #if HAVE_SYS_PARAM_H
 207 # include <sys/param.h>
 208 #endif
 209 ])
 210
 211 # For hddtemp module
 212 AC_CHECK_HEADERS(linux/major.h libgen.h)
 213
 214 # For the battery plugin
 215 AC_CHECK_HEADERS(IOKit/ps/IOPowerSources.h, [], [],
 216 [
 217 #if HAVE_IOKIT_IOKITLIB_H
 218 #  include <IOKit/IOKitLib.h>
 219 #endif
 220 #if HAVE_IOKIT_IOTYPES_H
 221 #  include <IOKit/IOTypes.h>
 222 #endif
 223 ])
 224
 225 # For the swap module
 226 AC_CHECK_HEADERS(sys/swap.h, [], [],
 227 [
 228 #if HAVE_SYS_TYPES_H
 229 #  include <sys/types.h>
 230 #endif
 231 #if HAVE_SYS_PARAM_H
 232 # include <sys/param.h>
 233 #endif
 234 ])
 235
 236 # For load module
 237 # For the processes plugin
 238 # For users module
 239 AC_CHECK_HEADERS(sys/loadavg.h linux/config.h utmp.h utmpx.h)
 240
 241 # For interface plugin
 242 AC_CHECK_HEADERS(ifaddrs.h)
 243 AC_CHECK_HEADERS(net/if.h, [], [],
 244 [
 245 #if HAVE_SYS_TYPES_H
 246 #  include <sys/types.h>
 247 #endif
 248 #if HAVE_SYS_SOCKET_H
 249 #  include <sys/socket.h>
 250 #endif
 251 ])
 252 AC_CHECK_HEADERS(linux/if.h, [], [],
 253 [
 254 #if HAVE_SYS_TYPES_H
 255 #  include <sys/types.h>
 256 #endif
 257 #if HAVE_SYS_SOCKET_H
 258 #  include <sys/socket.h>
 259 #endif
 260 ])
 261 AC_CHECK_HEADERS(linux/netdevice.h, [], [],
 262 [
 263 #if HAVE_SYS_TYPES_H
 264 #  include <sys/types.h>
 265 #endif
 266 #if HAVE_SYS_SOCKET_H
 267 #  include <sys/socket.h>
 268 #endif
 269 #if HAVE_LINUX_IF_H
 270 # include <linux/if.h>
 271 #endif
 272 ])
 273
 274 # For quota module
 275 AC_CHECK_HEADERS(sys/ucred.h, [], [],
 276 [
 277 #if HAVE_SYS_TYPES_H
 278 #  include <sys/types.h>
 279 #endif
 280 #if HAVE_SYS_PARAM_H
 281 # include <sys/param.h>
 282 #endif
 283 ])
 284
 285 # For mount interface
 286 AC_CHECK_HEADERS(sys/mount.h, [], [],
 287 [
 288 #if HAVE_SYS_TYPES_H
 289 #  include <sys/types.h>
 290 #endif
 291 #if HAVE_SYS_PARAM_H
 292 # include <sys/param.h>
 293 #endif
 294 ])
 295
 296 # For the email plugin
 297 AC_CHECK_HEADERS(linux/un.h, [], [],
 298 [
 299 #if HAVE_SYS_SOCKET_H
 300 #       include <sys/socket.h>
 301 #endif
 302 ])
 303
 304 AC_CHECK_HEADERS(pwd.h grp.h sys/un.h ctype.h limits.h sys/quota.h xfs/xqm.h fs_info.h fshelp.h paths.h mntent.h mnttab.h sys/fstyp.h sys/fs_types.h sys/mntent.h sys/mnttab.h sys/statfs.h sys/statvfs.h sys/vfs.h sys/vfstab.h kvm.h)
 305
 306 # For the dns plugin
 307 AC_CHECK_HEADERS(arpa/nameser.h)
 308 AC_CHECK_HEADERS(arpa/nameser_compat.h, [], [],
 309 [
 310 #if HAVE_ARPA_NAMESER_H
 311 # include <arpa/nameser.h>
 312 #endif
 313 ])
 314
 315 AC_CHECK_HEADERS(net/if_arp.h, [], [],
 316 [#if HAVE_SYS_SOCKET_H
 317 # include <sys/socket.h>
 318 #endif
 319 ])
 320 AC_CHECK_HEADERS(net/ppp_defs.h)
 321 AC_CHECK_HEADERS(net/if_ppp.h, [], [],
 322 [#if HAVE_NET_PPP_DEFS_H
 323 # include <net/ppp_defs.h>
 324 #endif
 325 ])
 326 AC_CHECK_HEADERS(netinet/if_ether.h, [], [],
 327 [#if HAVE_STDINT_H
 328 # include <stdint.h>
 329 #endif
 330 #if HAVE_SYS_TYPES_H
 331 # include <sys/types.h>
 332 #endif
 333 #if HAVE_SYS_SOCKET_H
 334 # include <sys/socket.h>
 335 #endif
 336 #if HAVE_NET_IF_H
 337 # include <net/if.h>
 338 #endif
 339 #if HAVE_NETINET_IN_H
 340 # include <netinet/in.h>
 341 #endif
 342 ])
 343
 344 # For the multimeter plugin
 345 have_termios_h="no"
 346 AC_CHECK_HEADERS(termios.h, [have_termios_h="yes"])
 347
 348 #
 349 # Checking for libraries
 350 #
 351 AC_CHECK_LIB(m, ext)
 352
 353 #
 354 # Checks for typedefs, structures, and compiler characteristics.
 355 #
 356 AC_C_CONST
 357 AC_TYPE_PID_T
 358 AC_TYPE_SIZE_T
 359 AC_TYPE_UID_T
 360 AC_HEADER_TIME
 361
 362 #
 363 # Checks for library functions.
 364 #
 365 AC_PROG_GCC_TRADITIONAL
 366 AC_CHECK_FUNCS(gettimeofday select strdup strtol getaddrinfo getnameinfo strchr memcpy strstr strcmp strncmp strncpy strlen strncasecmp strcasecmp openlog closelog)
 367
 368 AC_FUNC_STRERROR_R
 369
 370 AC_CHECK_FUNCS(getpwnam_r)
 371 AC_CHECK_FUNCS(getgrnam_r)
 372
 373 socket_needs_socket="no"
 374 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [socket_needs_socket="yes"], AC_MSG_ERROR(cannot find socket)))
 375 AM_CONDITIONAL(BUILD_WITH_LIBSOCKET, test "x$socket_needs_socket" = "xyes")
 376
 377 nanosleep_needs_rt="no"
 378 AC_CHECK_FUNCS(nanosleep, [], AC_CHECK_LIB(rt, nanosleep, [nanosleep_needs_rt="yes"], AC_MSG_ERROR(cannot find nanosleep)))
 379 AM_CONDITIONAL(BUILD_WITH_LIBRT, test "x$nanosleep_needs_rt" = "xyes")
 380
 381 AC_CHECK_FUNCS(regcomp regerror regexec regfree)
 382
 383 AC_CHECK_FUNCS(sysctlbyname, [have_sysctlbyname="yes"], [have_sysctlbyname="no"])
 384 AC_CHECK_FUNCS(host_statistics, [have_host_statistics="yes"], [have_host_statistics="no"])
 385 AC_CHECK_FUNCS(processor_info, [have_processor_info="yes"], [have_processor_info="no"])
 386 AC_CHECK_FUNCS(thread_info, [have_thread_info="yes"], [have_thread_info="no"])
 387 AC_CHECK_FUNCS(statfs, [have_statfs="yes"], [have_statfs="no"])
 388 AC_CHECK_FUNCS(statvfs, [have_statvfs="yes"], [have_statvfs="no"])
 389 AC_CHECK_FUNCS(getifaddrs, [have_getifaddrs="yes"], [have_getifaddrs="no"])
 390 AC_CHECK_FUNCS(syslog, [have_syslog="yes"], [have_syslog="no"])
 391 AC_CHECK_FUNCS(getutent, [have_getutent="yes"], [have_getutent="no"])
 392 AC_CHECK_FUNCS(getutxent, [have_getutxent="yes"], [have_getutxent="no"])
 393
 394 # For load module
 395 AC_CHECK_FUNCS(getloadavg, [have_getloadavg="yes"], [have_getloadavg="no"])
 396
 397 # Check for NAN
 398 AC_ARG_WITH(nan-emulation, [AS_HELP_STRING([--with-nan-emulation], [use emulated NAN. For crosscompiling only.])],
 399 [
 400  if test "x$withval" = "xno"; then
 401          nan_type="none"
 402  else if test "x$withval" = "xyes"; then
 403          nan_type="zero"
 404  else
 405          nan_type="$withval"
 406  fi; fi
 407 ],
 408 [nan_type="none"])
 409 if test "x$nan_type" = "xnone"; then
 410   AC_CACHE_CHECK([whether NAN is defined by default],
 411     [have_nan_default],
 412     AC_COMPILE_IFELSE(
 413       AC_LANG_PROGRAM(
 414       [[
 415 #include <stdlib.h>
 416 #include <math.h>
 417 static float foo = NAN;
 418       ]],
 419       [[
 420        if (isnan (foo))
 421         return 0;
 422        else
 423         return 1;
 424       ]]),
 425       [have_nan_default="yes"],
 426       [have_nan_default="no"]
 427     )
 428   )
 429   if test "x$have_nan_default" = "xyes"
 430   then
 431     nan_type="default"
 432   fi
 433 fi
 434 if test "x$nan_type" = "xnone"; then
 435   AC_CACHE_CHECK([whether NAN is defined by __USE_ISOC99],
 436     [have_nan_isoc],
 437     AC_COMPILE_IFELSE(
 438       AC_LANG_PROGRAM(
 439       [[
 440 #include <stdlib.h>
 441 #define __USE_ISOC99 1
 442 #include <math.h>
 443 static float foo = NAN;
 444       ]],
 445       [[
 446        if (isnan (foo))
 447         return 0;
 448        else
 449         return 1;
 450       ]]),
 451       [have_nan_isoc="yes"],
 452       [have_nan_isoc="no"]
 453     )
 454   )
 455   if test "x$have_nan_isoc" = "xyes"
 456   then
 457     nan_type="isoc99"
 458   fi
 459 fi
 460 if test "x$nan_type" = "xnone"; then
 461   AC_CACHE_CHECK([whether NAN can be defined by 0/0],
 462     [have_nan_zero],
 463     AC_RUN_IFELSE(
 464       AC_LANG_PROGRAM(
 465       [[
 466 #include <stdlib.h>
 467 #include <math.h>
 468 #ifdef NAN
 469 # undef NAN
 470 #endif
 471 #define NAN (0.0 / 0.0)
 472 #ifndef isnan
 473 # define isnan(f) ((f) != (f))
 474 #endif
 475 static float foo = NAN;
 476       ]],
 477       [[
 478        if (isnan (foo))
 479         return 0;
 480        else
 481         return 1;
 482       ]]),
 483       [have_nan_zero="yes"],
 484       [have_nan_zero="no"]
 485     )
 486   )
 487   if test "x$have_nan_zero" = "xyes"
 488   then
 489     nan_type="zero"
 490   fi
 491 fi
 492
 493 if test "x$nan_type" = "xdefault"; then
 494   AC_DEFINE(NAN_STATIC_DEFAULT, 1,
 495     [Define if NAN is defined by default and can initialize static variables.])
 496 else if test "x$nan_type" = "xisoc99"; then
 497   AC_DEFINE(NAN_STATIC_ISOC, 1,
 498     [Define if NAN is defined by __USE_ISOC99 and can initialize static variables.])
 499 else if test "x$nan_type" = "xzero"; then
 500   AC_DEFINE(NAN_ZERO_ZERO, 1,
 501     [Define if NAN can be defined as (0.0 / 0.0)])
 502 else
 503   AC_MSG_ERROR([Didn't find out how to statically initialize variables to NAN. Sorry.])
 504 fi; fi; fi
 505
 506 # For mount interface
 507 #AC_CHECK_FUNCS(getfsent getvfsent)
 508
 509 have_getfsstat="no"
 510 AC_CHECK_FUNCS(getfsstat, [have_getfsstat="yes"])
 511 have_getvfsstat="no"
 512 AC_CHECK_FUNCS(getvfsstat, [have_getvfsstat="yes"])
 513 have_listmntent="no"
 514 AC_CHECK_FUNCS(listmntent, [have_listmntent="yes"])
 515
 516 have_getmntent="no"
 517 AC_CHECK_FUNCS(getmntent, [have_getmntent="c"])
 518 if test "x$have_getmntent" = "xno"; then
 519         AC_CHECK_LIB(sun, getmntent, [have_getmntent="sun"])
 520 fi
 521 if test "x$have_getmntent" = "xno"; then
 522         AC_CHECK_LIB(seq, getmntent, [have_getmntent="seq"])
 523 fi
 524 if test "x$have_getmntent" = "xno"; then
 525         AC_CHECK_LIB(gen, getmntent, [have_getmntent="gen"])
 526 fi
 527
 528 if test "x$have_getmntent" = "xc"; then
 529         AC_CACHE_CHECK([whether getmntent takes one argument],
 530                 [have_one_getmntent],
 531                 AC_COMPILE_IFELSE(
 532                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 533 #include <mntent.h>
 534 #include "$srcdir/src/utils_mount.h"]],
 535                                 [[
 536                                  FILE *fh;
 537                                  struct mntent *me;
 538                                  fh = setmntent ("/etc/mtab", "r");
 539                                  me = getmntent (fh);
 540                                 ]]
 541                         ),
 542                         [have_one_getmntent="yes"],
 543                         [have_one_getmntent="no"]
 544                 )
 545         )
 546         AC_CACHE_CHECK([whether getmntent takes two arguments],
 547                 [have_two_getmntent],
 548                 AC_COMPILE_IFELSE(
 549                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 550 #include <sys/mnttab.h>
 551 #include "$srcdir/src/utils_mount.h"]],
 552                                 [[
 553                                  FILE *fh;
 554                                  struct mnttab mt;
 555                                  int status;
 556                                  fh = fopen ("/etc/mnttab", "r");
 557                                  status = getmntent (fh, &mt);
 558                                 ]]
 559                         ),
 560                         [have_two_getmntent="yes"],
 561                         [have_two_getmntent="no"]
 562                 )
 563         )
 564 fi
 565
 566 # Check for different versions of `getmntent' here..
 567
 568 if test "x$have_getmntent" = "xc"; then
 569         if test "x$have_one_getmntent" = "xyes"; then
 570                 AC_DEFINE(HAVE_ONE_GETMNTENT, 1,
 571                           [Define if the function getmntent exists and takes one argument.])
 572         fi
 573         if test "x$have_two_getmntent" = "xyes"; then
 574                 AC_DEFINE(HAVE_TWO_GETMNTENT, 1,
 575                           [Define if the function getmntent exists and takes two arguments.])
 576         fi
 577 fi
 578 if test "x$have_getmntent" = "xsun"; then
 579         AC_DEFINE(HAVE_SUN_GETMNTENT, 1,
 580                   [Define if the function getmntent exists. It's the version from libsun.])
 581 fi
 582 if test "x$have_getmntent" = "xseq"; then
 583         AC_DEFINE(HAVE_SEQ_GETMNTENT, 1,
 584                   [Define if the function getmntent exists. It's the version from libseq.])
 585 fi
 586 if test "x$have_getmntent" = "xgen"; then
 587         AC_DEFINE(HAVE_GEN_GETMNTENT, 1,
 588                   [Define if the function getmntent exists. It's the version from libgen.])
 589 fi
 590
 591 # Check for structures
 592 AC_CHECK_MEMBERS([struct if_data.ifi_ibytes, struct if_data.ifi_opackets, struct if_data.ifi_ierrors],
 593         [AC_DEFINE(HAVE_STRUCT_IF_DATA, 1, [Define if struct if_data exists and is usable.])],
 594         [],
 595         [
 596         #include <sys/types.h>
 597         #include <sys/socket.h>
 598         #include <net/if.h>
 599         ])
 600 AC_CHECK_MEMBERS([struct net_device_stats.rx_bytes, struct net_device_stats.tx_packets, struct net_device_stats.rx_errors],
 601         [AC_DEFINE(HAVE_STRUCT_NET_DEVICE_STATS, 1, [Define if struct net_device_stats exists and is usable.])],
 602         [],
 603         [
 604         #include <sys/types.h>
 605         #include <sys/socket.h>
 606         #include <linux/if.h>
 607         #include <linux/netdevice.h>
 608         ])
 609
 610 AC_CHECK_MEMBERS([struct udphdr.uh_dport, struct udphdr.uh_sport], [], [],
 611 [#if HAVE_STDINT_H
 612 # include <stdint.h>
 613 #endif
 614 #if HAVE_SYS_TYPES_H
 615 # include <sys/types.h>
 616 #endif
 617 #if HAVE_NETINET_IN_SYSTM_H
 618 # include <netinet/in_systm.h>
 619 #endif
 620 #if HAVE_NETINET_IN_H
 621 # include <netinet/in.h>
 622 #endif
 623 #if HAVE_NETINET_IP_H
 624 # include <netinet/ip.h>
 625 #endif
 626 #if HAVE_NETINET_UDP_H
 627 # include <netinet/udp.h>
 628 #endif
 629 ])
 630 AC_CHECK_MEMBERS([struct udphdr.dest, struct udphdr.source], [], [],
 631 [#if HAVE_STDINT_H
 632 # include <stdint.h>
 633 #endif
 634 #if HAVE_SYS_TYPES_H
 635 # include <sys/types.h>
 636 #endif
 637 #if HAVE_NETINET_IN_SYSTM_H
 638 # include <netinet/in_systm.h>
 639 #endif
 640 #if HAVE_NETINET_IN_H
 641 # include <netinet/in.h>
 642 #endif
 643 #if HAVE_NETINET_IP_H
 644 # include <netinet/ip.h>
 645 #endif
 646 #if HAVE_NETINET_UDP_H
 647 # include <netinet/udp.h>
 648 #endif
 649 ])
 650
 651 AC_CHECK_MEMBERS([kstat_io_t.nwritten, kstat_io_t.writes, kstat_io_t.nwrites, kstat_io_t.wtime],
 652         [],
 653         [],
 654         [
 655 #if HAVE_KSTAT_H
 656 # include <kstat.h>
 657 #endif
 658         ])
 659
 660 with_libresolv="yes"
 661 AC_CHECK_LIB(resolv, res_search,
 662 [
 663         AC_DEFINE(HAVE_LIBRESOLV, 1, [Define to 1 if you have the 'resolv' library (-lresolv).])
 664 ],
 665 [with_libresolv="no"])
 666 AM_CONDITIONAL(BUILD_WITH_LIBRESOLV, test "x$with_libresolv" = "xyes")
 667
 668
 669 m4_divert_once([HELP_WITH], [
 670 collectd additional packages:])
 671
 672 # AC_ARG_WITH (package, help-string, [action-if-given], [action-if-not-given])
 673 AC_ARG_WITH(rrdtool, [AS_HELP_STRING([--with-rrdtool@<:@=PREFIX@:>@], [Path to rrdtool.])],
 674 [       if test "x$withval" != "xno" && test "x$withval" != "xyes"
 675         then
 676                 LDFLAGS="$LDFLAGS -L$withval/lib"
 677                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 678                 with_rrdtool="yes"
 679         fi
 680 ], [with_rrdtool="yes"])
 681 if test "x$with_rrdtool" = "xyes"
 682 then
 683         AC_CHECK_LIB(rrd, rrd_update,
 684         [
 685                 AC_DEFINE(HAVE_LIBRRD, 1, [Define to 1 if you have the rrd library (-lrrd).])
 686         ],
 687         [with_rrdtool="no (librrd not found)"], [-lm])
 688 fi
 689 if test "x$with_rrdtool" = "xyes"
 690 then
 691         AC_CHECK_HEADERS(rrd.h,, [with_rrdtool="no (rrd.h not found)"])
 692 fi
 693 if test "x$with_rrdtool" = "xyes"
 694 then
 695         collect_rrdtool=1
 696 else
 697         collect_rrdtool=0
 698 fi
 699 AC_DEFINE_UNQUOTED(COLLECT_RRDTOOL, [$collect_rrdtool],
 700         [Wether or not to use rrdtool library])
 701 AM_CONDITIONAL(BUILD_WITH_RRDTOOL, test "x$with_rrdtool" = "xyes")
 702
 703 AC_ARG_WITH(libpthread, [AS_HELP_STRING([--with-libpthread=@<:@=PREFIX@:>@], [Path to libpthread.])],
 704 [       if test "x$withval" != "xno" -a "x$withval" != "xyes"
 705         then
 706                 LDFLAGS="$LDFLAGS -L$withval/lib"
 707                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 708                 with_libpthread="yes"
 709         else
 710                 if test "x$withval" = "xno"
 711                 then
 712                         with_libpthread="no (disabled)"
 713                 fi
 714         fi
 715 ], [with_libpthread="yes"])
 716 if test "x$with_libpthread" = "xyes"
 717 then
 718         AC_CHECK_LIB(pthread, pthread_create, [with_libpthread="yes"], [with_libpthread="no (libpthread not found)"], [])
 719 fi
 720 if test "x$with_libpthread" = "xyes"
 721 then
 722         AC_CHECK_HEADERS(pthread.h,, [with_libpthread="no (pthread.h not found)"])
 723 fi
 724 if test "x$with_libpthread" = "xyes"
 725 then
 726         collect_pthread=1
 727 else
 728         collect_pthread=0
 729 fi
 730 AC_DEFINE_UNQUOTED(HAVE_LIBPTHREAD, [$collect_pthread],
 731         [Wether or not to use pthread (POSIX threads) library])
 732 AM_CONDITIONAL(BUILD_WITH_LIBPTHREAD, test "x$with_libpthread" = "xyes")
 733
 734 if test "x$ac_system" = "xSolaris"
 735 then
 736         with_kstat="yes"
 737         with_devinfo="yes"
 738 else
 739         with_kstat="no (Solaris only)"
 740         with_devinfo="no (Solaris only)"
 741 fi
 742
 743 if test "x$with_kstat" = "xyes"
 744 then
 745         AC_CHECK_LIB(kstat, kstat_open, [with_kstat="yes"], [with_kstat="no (libkstat not found)"], [])
 746 fi
 747 if test "x$with_kstat" = "xyes"
 748 then
 749         AC_CHECK_LIB(devinfo, di_init, [with_devinfo="yes"], [with_devinfo="no (not found)"], [])
 750         AC_CHECK_HEADERS(kstat.h,, [with_kstat="no (kstat.h not found)"])
 751 fi
 752 if test "x$with_kstat" = "xyes"
 753 then
 754         AC_DEFINE(HAVE_LIBKSTAT, 1,
 755                   [Define to 1 if you have the 'kstat' library (-lkstat)])
 756 fi
 757 AM_CONDITIONAL(BUILD_WITH_LIBKSTAT, test "x$with_kstat" = "xyes")
 758 AM_CONDITIONAL(BUILD_WITH_LIBDEVINFO, test "x$with_devinfo" = "xyes")
 759
 760 ### BEGIN of check for libcurl ###
 761 with_curl_config="curl-config"
 762 with_curl_cflags=""
 763 with_curl_libs=""
 764 AC_ARG_WITH(libcurl, [AS_HELP_STRING([--with-libcurl@<:@=PREFIX@:>@], [Path to libcurl.])],
 765 [
 766         if test "x$withval" = "xno"
 767         then
 768                 with_libcurl="no"
 769         else if test "x$withval" = "xyes"
 770         then
 771                 with_libcurl="yes"
 772         else
 773                 if test -f "$withval" && test -x "$withval"
 774                 then
 775                         with_curl_config="$withval"
 776                 else if test -x "$withval/bin/curl-config"
 777                 then
 778                         with_curl_config="$withval/bin/curl-config"
 779                 fi; fi
 780                 with_libcurl="yes"
 781         fi; fi
 782 ],
 783 [
 784         with_libcurl="yes"
 785 ])
 786 if test "x$with_libcurl" = "xyes"
 787 then
 788         with_curl_cflags=`$with_curl_config --cflags 2>/dev/null`
 789         curl_config_status=$?
 790
 791         if test $curl_config_status -ne 0
 792         then
 793                 with_libcurl="no ($with_curl_config failed)"
 794         else
 795                 SAVE_CFLAGS=$CFLAGS
 796                 CFLAGS="$CFLAGS $with_curl_cflags"
 797
 798                 AC_CHECK_HEADERS(curl/curl.h, [], [with_libcurl="no (curl/curl.h not found)"], [])
 799
 800                 CFLAGS="$SAVE_CFLAGS"
 801         fi
 802 fi
 803 if test "x$with_libcurl" = "xyes"
 804 then
 805         with_curl_libs=`$with_curl_config --libs 2>/dev/null`
 806         curl_config_status=$?
 807
 808         if test $curl_config_status -ne 0
 809         then
 810                 with_libcurl="no ($with_curl_config failed)"
 811         else
 812                 AC_CHECK_LIB(curl, curl_easy_init,
 813                  [with_libcurl="yes"],
 814                  [with_libcurl="no (symbol 'curl_easy_init' not found)"],
 815                  [$with_curl_libs])
 816         fi
 817 fi
 818 if test "x$with_libcurl" = "xyes"
 819 then
 820         BUILD_WITH_LIBCURL_CFLAGS="$with_curl_cflags"
 821         BUILD_WITH_LIBCURL_LIBS="$with_curl_libs"
 822         AC_SUBST(BUILD_WITH_LIBCURL_CFLAGS)
 823         AC_SUBST(BUILD_WITH_LIBCURL_LIBS)
 824 fi
 825 AM_CONDITIONAL(BUILD_WITH_LIBCURL, test "x$with_libcurl" = "xyes")
 826 ### END of check for libcurl ###
 827
 828 with_libiokit="no"
 829 collectd_libiokit=0
 830 AC_CHECK_LIB(IOKit, IOServiceGetMatchingServices,
 831 [
 832         with_libiokit="yes"
 833         collectd_libiokit=1
 834 ],
 835 [
 836         with_libiokit="no"
 837         collectd_libiokit=0
 838 ])
 839 AC_DEFINE_UNQUOTED(COLLECT_LIBIOKIT, [$collect_libiokit], [Wether or not to use the IOKit library])
 840 AM_CONDITIONAL(BUILD_WITH_LIBIOKIT, test "x$with_libiokit" = "xyes")
 841
 842 with_libstatgrab="yes"
 843 with_libdevstat="no"
 844 AC_ARG_WITH(libstatgrab, [AS_HELP_STRING([--with-libstatgrab@<:@=PREFIX@:>@], [Path to libstatgrab.])],
 845 [
 846         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 847         then
 848                 LDFLAGS="$LDFLAGS -L$withval/lib"
 849                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 850                 with_libstatgrab="yes"
 851         fi
 852 ],
 853 [
 854         if test "x$ac_system" == "xunknown"
 855         then
 856                 with_libstatgrab="yes"
 857         else
 858                 with_libstatgrab="no"
 859         fi
 860 ])
 861 if test "x$with_libstatgrab" = "xyes"
 862 then
 863         AC_CHECK_LIB(statgrab, sg_init, [with_libstatgrab="yes"], [with_libstatgrab="no (libstatgrab not found)"])
 864 fi
 865 if test "x$with_libstatgrab" = "xyes"
 866 then
 867         AC_CHECK_HEADERS(statgrab.h,,    [with_libstatgrab="no (statgrab.h not found)"])
 868 fi
 869 if test "x$with_libstatgrab" = "xyes"
 870 then
 871         AC_CHECK_LIB(devstat, getdevs, [with_libdevstat="yes"], [with_libdevstat="no"])
 872 fi
 873 if test "x$with_libstatgrab" = "xyes"
 874 then
 875         collect_libstatgrab=1
 876 else
 877         collect_libstatgrab=0
 878 fi
 879 AC_DEFINE_UNQUOTED(COLLECT_LIBSTATGRAB, [$collect_libstatgrab],
 880         [Wether or not to use statgrab library])
 881 AM_CONDITIONAL(BUILD_WITH_LIBSTATGRAB, test "x$with_libstatgrab" = "xyes")
 882 AM_CONDITIONAL(BUILD_WITH_LIBDEVSTAT,  test "x$with_libdevstat"  = "xyes")
 883
 884 AC_CHECK_LIB(kvm, kvm_getswapinfo, [with_libkvm="yes"], [with_libkvm="no"])
 885 if test "x$with_libkvm" = "xyes"
 886 then
 887         AC_DEFINE(HAVE_LIBKVM, 1, [Define to 1 if you have the 'kvm' library (-lkvm)])
 888 fi
 889 AM_CONDITIONAL(BUILD_WITH_LIBKVM, test "x$with_libkvm" = "xyes")
 890
 891 AC_ARG_WITH(lm-sensors, [AS_HELP_STRING([--with-lm-sensors@<:@=PREFIX@:>@], [Path to lm_sensors.])],
 892 [
 893         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 894         then
 895                 LDFLAGS="$LDFLAGS -L$withval/lib"
 896                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 897                 with_lm_sensors="yes"
 898         fi
 899 ],
 900 [
 901         if test "x$ac_system" = "xLinux"
 902         then
 903                 with_lm_sensors="yes"
 904         else
 905                 with_lm_sensors="no (Linux only library)"
 906         fi
 907 ])
 908 if test "x$with_lm_sensors" = "xyes"
 909 then
 910         AC_CHECK_LIB(sensors, sensors_init,
 911         [
 912                 AC_DEFINE(HAVE_LIBSENSORS, 1, [Define to 1 if you have the sensors library (-lsensors).])
 913         ],
 914         [with_lm_sensors="no (libsensors not found)"])
 915 fi
 916 if test "x$with_lm_sensors" = "xyes"
 917 then
 918         AC_CHECK_HEADERS(sensors/sensors.h,
 919         [
 920                 AC_DEFINE(HAVE_SENSORS_SENSORS_H, 1, [Define to 1 if you have the <sensors/sensors.h> header file.])
 921         ],
 922         [with_lm_sensors="no (sensors/sensors.h not found)"])
 923 fi
 924 if test "x$with_lm_sensors" = "xyes"
 925 then
 926         collect_lm_sensors=1
 927 else
 928         collect_lm_sensors=0
 929 fi
 930 AC_DEFINE_UNQUOTED(COLLECT_LM_SENSORS, [$collect_lm_sensors],
 931         [Wether or not to use sensors library])
 932 AM_CONDITIONAL(BUILD_WITH_LM_SENSORS, test "x$with_lm_sensors" = "xyes")
 933
 934 with_mysql_config="mysql_config"
 935 with_mysql_cflags=""
 936 with_mysql_libs=""
 937 AC_ARG_WITH(libmysql, [AS_HELP_STRING([--with-libmysql@<:@=PREFIX@:>@], [Path to libmysql.])],
 938 [
 939         if test "x$withval" = "xno"
 940         then
 941                 with_libmysql="no"
 942         else if test "x$withval" = "xyes"
 943         then
 944                 with_libmysql="yes"
 945         else
 946                 if test -f "$withval" && test -x "$withval";
 947                 then
 948                         with_mysql_config="$withval"
 949                 else if test -x "$withval/bin/mysql_config"
 950                 then
 951                         with_mysql_config="$withval/bin/mysql_config"
 952                 fi; fi
 953                 with_libmysql="yes"
 954         fi; fi
 955 ],
 956 [
 957         with_libmysql="yes"
 958 ])
 959 if test "x$with_libmysql" = "xyes"
 960 then
 961         with_mysql_cflags=`$with_mysql_config --cflags 2>/dev/null`
 962         mysql_config_status=$?
 963
 964         if test $mysql_config_status -ne 0
 965         then
 966                 with_libmysql="no"
 967         else
 968                 SAVE_CFLAGS=$CFLAGS
 969                 CFLAGS="$CFLAGS $with_mysql_cflags"
 970
 971                 AC_CHECK_HEADERS(mysql/mysql.h, [], [with_libmysql="no (mysql/mysql.h not found)"], [])
 972
 973                 CFLAGS="$SAVE_CFLAGS"
 974         fi
 975 fi
 976 if test "x$with_libmysql" = "xyes"
 977 then
 978         with_mysql_libs=`$with_mysql_config --libs 2>/dev/null`
 979         mysql_config_status=$?
 980
 981         if test $mysql_config_status -ne 0
 982         then
 983                 with_libmysql="no"
 984         else
 985                 AC_CHECK_LIB(mysqlclient, mysql_init,
 986                  [with_libmysql="yes"],
 987                  [with_libmysql="no (symbol 'mysql_init' not found)"],
 988                  [$with_mysql_libs])
 989         fi
 990 fi
 991 if test "x$with_libmysql" = "xyes"
 992 then
 993         BUILD_WITH_LIBMYSQL_CFLAGS="$with_mysql_cflags"
 994         BUILD_WITH_LIBMYSQL_LIBS="$with_mysql_libs"
 995         AC_SUBST(BUILD_WITH_LIBMYSQL_CFLAGS)
 996         AC_SUBST(BUILD_WITH_LIBMYSQL_LIBS)
 997 fi
 998 AM_CONDITIONAL(BUILD_WITH_LIBMYSQL, test "x$with_libmysql" = "xyes")
 999
1000 with_own_liboconfig="no"
1001 liboconfig_LDFLAGS="$LDFLAGS"
1002 liboconfig_CPPFLAGS="$CPPFLAGS"
1003 AC_ARG_WITH(liboconfig, [AS_HELP_STRING([--with-liboconfig@<:@=PREFIX@:>@], [Path to liboconfig.])],
1004 [
1005         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1006         then
1007                 if test -d "$withval/lib"
1008                 then
1009                         liboconfig_LDFLAGS="$LDFLAGS -L$withval/lib"
1010                 fi
1011                 if test -d "$withval/include"
1012                 then
1013                         liboconfig_CPPFLAGS="$CPPFLAGS -I$withval/include"
1014                 fi
1015         fi
1016         if test "x$withval" = "xno"
1017         then
1018                 AC_MSG_ERROR("liboconfig is required")
1019         fi
1020 ],
1021 [
1022         with_liboconfig="yes"
1023 ])
1024
1025 save_LDFLAGS="$LDFLAGS"
1026 save_CPPFLAGS="$CPPFLAGS"
1027 LDFLAGS="$liboconfig_LDFLAGS"
1028 CPPFLAGS="$liboconfig_CPPFLAGS"
1029 AC_CHECK_LIB(oconfig, oconfig_parse_fh,
1030 [
1031         with_liboconfig="yes"
1032         with_own_liboconfig="no"
1033 ],
1034 [
1035         with_liboconfig="yes"
1036         with_own_liboconfig="yes"
1037         LDFLAGS="$save_LDFLAGS"
1038         CPPFLAGS="$save_CPPFLAGS"
1039 ])
1040
1041 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOCONFIG, test "x$with_own_liboconfig" = "xyes")
1042 if test "x$with_own_liboconfig" = "xyes"
1043 then
1044         with_liboconfig="yes (shipped version)"
1045 fi
1046
1047 #with_liboping="yes"
1048 with_own_liboping="no"
1049 liboping_LDFLAGS="$LDFLAGS"
1050 liboping_CPPFLAGS="$CPPFLAGS"
1051 AC_ARG_WITH(liboping, [AS_HELP_STRING([--with-liboping@<:@=PREFIX@:>@], [Path to liboping.])],
1052 [
1053         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1054         then
1055                 if test -d "$withval/lib"
1056                 then
1057                         liboping_LDFLAGS="$LDFLAGS -L$withval/lib"
1058                 fi
1059                 if test -d "$withval/include"
1060                 then
1061                         liboping_CPPFLAGS="$CPPFLAGS -I$withval/include"
1062                 fi
1063         fi
1064         if test "x$withval" = "xno"
1065         then
1066                 with_liboping="no"
1067                 with_own_liboping="no"
1068         fi
1069 ],
1070 [
1071         #753
1072         with_liboping="yes"
1073 ])
1074
1075 if test "x$with_liboping" = "xyes"
1076 then
1077         save_LDFLAGS="$LDFLAGS"
1078         save_CPPFLAGS="$CPPFLAGS"
1079         LDFLAGS="$liboping_LDFLAGS"
1080         CPPFLAGS="$liboping_CPPFLAGS"
1081         AC_CHECK_LIB(oping, ping_construct,
1082         [
1083                 with_liboping="yes"
1084                 with_own_liboping="no"
1085         ],
1086         [
1087                 with_liboping="yes"
1088                 with_own_liboping="yes"
1089                 LDFLAGS="$save_LDFLAGS"
1090                 CPPFLAGS="$save_CPPFLAGS"
1091         ])
1092 fi
1093 AM_CONDITIONAL(BUILD_WITH_LIBOPING, test "x$with_liboping" = "xyes")
1094 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOPING, test "x$with_own_liboping" = "xyes")
1095
1096 AC_ARG_WITH(libpcap, [AS_HELP_STRING([--with-libpcap@<:@=PREFIX@:>@], [Path to libpcap.])],
1097 [
1098         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1099         then
1100                 LDFLAGS="$LDFLAGS -L$withval/lib"
1101                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1102                 with_libpcap="yes"
1103         fi
1104 ],
1105 [
1106         with_libpcap="yes"
1107 ])
1108 if test "x$with_libpcap" = "xyes"
1109 then
1110         AC_CHECK_LIB(pcap, pcap_open_live,
1111         [
1112                 AC_DEFINE(HAVE_LIBPCAP, 1, [Define to 1 if you have the pcap library (-lpcap).])
1113         ], [with_libpcap="no (libpcap not found)"])
1114 fi
1115 if test "x$with_libpcap" = "xyes"
1116 then
1117         AC_CHECK_HEADERS(pcap.h,
1118         [
1119                 AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1120         ], [with_libpcap="no (pcap.h not found)"])
1121 fi
1122 if test "x$with_libpcap" = "xyes"
1123 then
1124         collect_libpcap=1
1125 else
1126         collect_libpcap=0
1127 fi
1128 AC_DEFINE_UNQUOTED(COLLECT_LIBPCAP, [$collect_libpcap],
1129         [Wether or not to use the pcap library])
1130 AM_CONDITIONAL(BUILD_WITH_LIBPCAP, test "x$with_libpcap" = "xyes")
1131
1132 perl_interpreter="perl"
1133 AC_ARG_WITH(libperl, [AS_HELP_STRING([--with-libperl@<:@=PREFIX@:>@], [Path to libperl.])],
1134 [
1135         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1136         then
1137                 LDFLAGS="$LDFLAGS -L$withval/lib"
1138                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1139                 perl_interpreter="$withval/bin/perl"
1140                 with_libperl="yes"
1141         fi
1142 ],
1143 [
1144         with_libperl="yes"
1145 ])
1146 if test "x$with_libperl" = "xyes"
1147 then
1148   SAVE_CFLAGS=$CFLAGS
1149   SAVE_LDFLAGS=$LDFLAGS
1150   PERL_CFLAGS=`$perl_interpreter -MExtUtils::Embed -e ccopts`
1151   PERL_LDFLAGS=`$perl_interpreter -MExtUtils::Embed -e ldopts`
1152   CFLAGS="$CFLAGS $PERL_CFLAGS"
1153   LDFLAGS="$LDFLAGS $PERL_LDFLAGS"
1154
1155   AC_CACHE_CHECK([for libperl],
1156     [have_libperl],
1157     AC_LINK_IFELSE(
1158       AC_LANG_PROGRAM(
1159       [[
1160 #include <EXTERN.h>
1161 #include <perl.h>
1162 #include <XSUB.h>
1163       ]],
1164       [[
1165        PerlInterpreter *perl = NULL;
1166        Perl_load_module (perl, PERL_LOADMOD_NOIMPORT,
1167                          newSVpv ("Collectd::Plugin::FooBar", 24),
1168                          Nullsv);
1169       ]]),
1170       [have_libperl="yes"],
1171       [have_libperl="no"]
1172     )
1173   )
1174
1175   if test "x$have_libperl" = "xyes"
1176   then
1177           AC_DEFINE(HAVE_LIBPERL, 1, [Define if libperl is present and usable.])
1178           AC_SUBST(PERL_CFLAGS)
1179           AC_SUBST(PERL_LDFLAGS)
1180   else
1181           with_libperl="no"
1182   fi
1183
1184   CFLAGS=$SAVE_CFLAGS
1185   LDFLAGS=$SAVE_LDFLAGS
1186 fi
1187 AM_CONDITIONAL(BUILD_WITH_LIBPERL, test "x$with_libperl" = "xyes")
1188
1189 AC_ARG_WITH(libiptc, [AS_HELP_STRING([--with-libiptc@<:@=PREFIX@:>@], [Path to libiptc.])],
1190 [
1191         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1192         then
1193                 LDFLAGS="$LDFLAGS -L$withval/lib"
1194                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1195                 with_libiptc="yes"
1196         fi
1197 ],
1198 [
1199         if test "x$ac_system" = "xLinux"
1200         then
1201                 with_libiptc="yes"
1202         else
1203                 with_libiptc="no (Linux only)"
1204         fi
1205 ])
1206 if test "x$with_libiptc" = "xyes"
1207 then
1208         AC_CHECK_LIB(iptc, iptc_init,
1209         [
1210                 AC_DEFINE(HAVE_LIBIPTC, 1, [Define to 1 if you have the iptc library (-liptc).])
1211         ], [with_libiptc="no (libiptc not found)"])
1212 fi
1213 if test "x$with_libiptc" = "xyes"
1214 then
1215         AC_CHECK_HEADERS(libiptc/libiptc.h,
1216         [
1217                 AC_DEFINE(HAVE_LIBIPTC_LIBIPTC_H, 1, [Define to 1 if you have the <libiptc/libiptc.h> header file.])
1218         ], [with_libiptc="no (libiptc/libiptc.h not found)"])
1219 fi
1220 if test "x$with_libiptc" = "xyes"
1221 then
1222         collect_libiptc=1
1223 else
1224         collect_libiptc=0
1225 fi
1226 AM_CONDITIONAL(BUILD_WITH_LIBIPTC, test "x$with_libiptc" = "xyes")
1227
1228 AC_ARG_WITH(libnetsnmp, [AS_HELP_STRING([--with-libnetsnmp@<:@=PREFIX@:>@], [Path to the Net-SNMPD library.])],
1229 [
1230         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1231         then
1232                 LDFLAGS="$LDFLAGS -L$withval/lib"
1233                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1234                 with_libnetsnmp="yes"
1235         fi
1236 ],
1237 [with_libnetsnmp="yes"])
1238 if test "x$with_libnetsnmp" = "xyes"
1239 then
1240         AC_CHECK_LIB(netsnmp, init_snmp,
1241         [
1242                 AC_DEFINE(HAVE_LIBSNMP, 1, [Define to 1 if you have the Net-SNMP library (-lnetsnmp).])
1243         ], [with_libnetsnmp="no (libnetsnmp not found)"])
1244 fi
1245 if test "x$with_libnetsnmp" = "xyes"
1246 then
1247         AC_CHECK_HEADERS(net-snmp/net-snmp-config.h,
1248         [
1249                 AC_DEFINE(HAVE_NET_SNMP_NET_SNMP_CONFIG_H, 1, [Define to 1 if you have the <net-snmp/net-snmp-config.h> header file.])
1250         ], [with_libnetsnmp="no (net-snmp/net-snmp-config.h not found)"])
1251 fi
1252 AM_CONDITIONAL(BUILD_WITH_LIBNETSNMP, test "x$with_libnetsnmp" = "xyes")
1253
1254 with_upsclient_config="libupsclient-config"
1255 with_upsclient_cflags=""
1256 with_upsclient_libs=""
1257 AC_ARG_WITH(libupsclient, [AS_HELP_STRING([--with-libupsclient@<:@=PREFIX@:>@], [Path to libupsclient.])],
1258 [
1259         if test "x$withval" = "xno"
1260         then
1261                 with_libupsclient="no"
1262         else
1263                 if test "x$withval" != "xyes"
1264                 then
1265                         if test -f "$withval" && test -x "$withval";
1266                         then
1267                                 with_upsclient_config="$withval"
1268                         else
1269                                 with_upsclient_config="$withval/bin/libupsclient-config"
1270                         fi
1271                 fi
1272                 with_libupsclient="yes"
1273         fi
1274 ],
1275 [
1276         with_libupsclient="yes"
1277 ])
1278 if test "x$with_libupsclient" = "xyes"
1279 then
1280         with_upsclient_cflags=`$with_upsclient_config --cflags 2>/dev/null`
1281         upsclient_config_status=$?
1282
1283         if test $upsclient_config_status -ne 0
1284         then
1285                 with_libupsclient="no ($with_upsclient_config failed)"
1286         fi
1287 fi
1288 if test "x$with_libupsclient" = "xyes"
1289 then
1290         SAVE_CFLAGS="$CFLAGS"
1291         CFLAGS="$CFLAGS $with_upsclient_cflags"
1292
1293         AC_CHECK_HEADERS(upsclient.h, [], [with_libupsclient="no (upsclient.h not found)"])
1294
1295         CFLAGS="$SAVE_CFLAGS"
1296 fi
1297 if test "x$with_libupsclient" = "xyes"
1298 then
1299         with_upsclient_libs=`$with_upsclient_config --libs 2>/dev/null`
1300         upsclient_config_status=$?
1301
1302         if test $upsclient_config_status -ne 0
1303         then
1304                 with_libupsclient="no ($with_upsclient_config failed)"
1305         fi
1306 fi
1307 if test "x$with_libupsclient" = "xyes"
1308 then
1309         AC_CHECK_LIB(upsclient, upscli_connect,
1310         [
1311                 BUILD_WITH_LIBUPSCLIENT_CFLAGS="$with_upsclient_cflags"
1312                 BUILD_WITH_LIBUPSCLIENT_LIBS="$with_upsclient_libs"
1313                 AC_SUBST(BUILD_WITH_LIBUPSCLIENT_CFLAGS)
1314                 AC_SUBST(BUILD_WITH_LIBUPSCLIENT_LIBS)
1315         ],
1316         [
1317                 with_libupsclient="no (symbol 'upscli_connect' not found)"
1318         ], [$with_upsclient_libs])
1319 fi
1320 if test "x$with_libupsclient" = "xyes"
1321 then
1322         AC_CHECK_TYPES([UPSCONN_t, UPSCONN], [], [],
1323 [#include <stdlib.h>
1324 #include <stdio.h>
1325 #include <upsclient.h>])
1326 fi
1327 AM_CONDITIONAL(BUILD_WITH_LIBUPSCLIENT, test "x$with_libupsclient" = "xyes")
1328
1329 ### BEGIN of check for libxmms ###
1330 with_xmms_config="xmms-config"
1331 with_xmms_cflags=""
1332 with_xmms_libs=""
1333 AC_ARG_WITH(libxmms, [AS_HELP_STRING([--with-libxmms@<:@=PREFIX@:>@], [Path to libxmms.])],
1334 [
1335         if test "x$withval" != "xno" -a "x$withval" != "xyes"
1336         then
1337                 if test -f "$withval" && test -x "$withval";
1338                 then
1339                         with_xmms_config="$withval"
1340                 else if test -x "$withval/bin/xmms-config"
1341                 then
1342                         with_xmms_config="$withval/bin/xmms-config"
1343                 fi; fi
1344                 with_libxmms="yes"
1345         else if test "x$withval" = "xno"
1346         then
1347                 with_libxmms="no"
1348         else
1349                 with_libxmms="yes"
1350         fi; fi
1351 ],
1352 [
1353         with_libxmms="yes"
1354 ])
1355 if test "x$with_libxmms" = "xyes"
1356 then
1357         with_xmms_cflags=`$with_xmms_config --cflags 2>/dev/null`
1358         xmms_config_status=$?
1359
1360         if test $xmms_config_status -ne 0
1361         then
1362                 with_libxmms="no"
1363         fi
1364 fi
1365 if test "x$with_libxmms" = "xyes"
1366 then
1367         with_xmms_libs=`$with_xmms_config --libs 2>/dev/null`
1368         xmms_config_status=$?
1369
1370         if test $xmms_config_status -ne 0
1371         then
1372                 with_libxmms="no"
1373         fi
1374 fi
1375 if test "x$with_libxmms" = "xyes"
1376 then
1377         AC_CHECK_LIB(xmms, xmms_remote_get_info,
1378         [
1379                 BUILD_WITH_LIBXMMS_CFLAGS="$with_xmms_cflags"
1380                 BUILD_WITH_LIBXMMS_LIBS="$with_xmms_libs"
1381                 AC_SUBST(BUILD_WITH_LIBXMMS_CFLAGS)
1382                 AC_SUBST(BUILD_WITH_LIBXMMS_LIBS)
1383         ],
1384         [
1385                 with_libxmms="no"
1386         ],
1387         [$with_xmms_libs])
1388 fi
1389 with_libxmms_numeric=0
1390 if test "x$with_libxmms" = "xyes"
1391 then
1392         with_libxmms_numeric=1
1393 fi
1394 AC_DEFINE_UNQUOTED(HAVE_LIBXMMS, [$with_libxmms_numeric], [Define to 1 if you have the 'xmms' library (-lxmms).])
1395 AM_CONDITIONAL(BUILD_WITH_LIBXMMS, test "x$with_libxmms" = "xyes")
1396 ### END of check for libxmms ###
1397
1398 with_libnetlink_cflags=""
1399 with_libnetlink_libs="-lnetlink"
1400 AC_ARG_WITH(libnetlink, [AS_HELP_STRING([--with-libnetlink@<:@=PREFIX@:>@], [Path to libnetlink.])],
1401 [
1402  echo "libnetlink: withval = $withval"
1403  if test "x$withval" = "xyes"
1404  then
1405          with_libnetlink="yes"
1406  else if test "x$withval" = "xno"
1407  then
1408          with_libnetlink="no"
1409  else
1410          if test -d "$withval/include"
1411          then
1412                  with_libnetlink_cflags="-I$withval/include"
1413                  with_libnetlink_libs="-L$withval/lib -lnetlink"
1414                  with_libnetlink="yes"
1415          else
1416                  AC_MSG_ERROR("no such directory: $withval/include")
1417          fi
1418  fi; fi
1419 ],
1420 [
1421  if test "x$ac_system" = "xLinux"
1422  then
1423          with_libnetlink="yes"
1424  else
1425          with_libnetlink="no (Linux only library)"
1426  fi
1427 ])
1428 if test "x$with_libnetlink" = "xyes"
1429 then
1430         SAVE_CFLAGS=$CFLAGS
1431         CFLAGS="$CFLAGS $with_libnetlink_cflags"
1432
1433         with_libnetlink="no (libnetlink.h not found)"
1434
1435         AC_CHECK_HEADERS(libnetlink.h iproute/libnetlink.h linux/libnetlink.h,
1436         [
1437          with_libnetlink="yes"
1438          break
1439         ], [],
1440 [#include <stdio.h>
1441 #include <sys/types.h>
1442 #include <asm/types.h>
1443 #include <sys/socket.h>
1444 #include <linux/netlink.h>
1445 #include <linux/rtnetlink.h>])
1446
1447         CFLAGS="$SAVE_CFLAGS"
1448 fi
1449 if test "x$with_libnetlink" = "xyes"
1450 then
1451         AC_CHECK_LIB(netlink, rtnl_open,
1452                      [with_libnetlink="yes"],
1453                      [with_libnetlink="no (symbol 'rtnl_open' not found)"],
1454                      [$with_libnetlink_libs])
1455 fi
1456 if test "x$with_libnetlink" = "xyes"
1457 then
1458         BUILD_WITH_LIBNETLINK_CFLAGS="$with_libnetlink_cflags"
1459         BUILD_WITH_LIBNETLINK_LIBS="$with_libnetlink_libs"
1460         AC_SUBST(BUILD_WITH_LIBNETLINK_CFLAGS)
1461         AC_SUBST(BUILD_WITH_LIBNETLINK_LIBS)
1462 fi
1463 AM_CONDITIONAL(BUILD_WITH_LIBNETLINK, test "x$with_libnetlink" = "xyes")
1464
1465 # Check for enabled/disabled features
1466 #
1467
1468 # AC_COLLECTD(name, enable/disable, info-text, feature/module)
1469 # ------------------------------------------------------------
1470 dnl
1471 m4_define([my_toupper], [m4_translit([$1], m4_defn([m4_cr_letters]), m4_defn([m4_cr_LETTERS]))])
1472 dnl
1473 AC_DEFUN(
1474         [AC_COLLECTD],
1475         [
1476         m4_if([$1], [], [AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 1st argument must not be empty])])dnl
1477         m4_if(
1478                 [$2],
1479                 [enable],
1480                 [dnl
1481                 m4_define([EnDis],[disabled])dnl
1482                 m4_define([YesNo],[no])dnl
1483                 ],dnl
1484                 [m4_if(
1485                         [$2],
1486                         [disable],
1487                         [dnl
1488                         m4_define([EnDis],[enabled])dnl
1489                         m4_define([YesNo],[yes])dnl
1490                         ],
1491                         [dnl
1492                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 2nd argument must be either enable or disable])dnl
1493                         ]dnl
1494                 )]dnl
1495         )dnl
1496         m4_if([$3], [feature], [],
1497                 [m4_if(
1498                         [$3], [module], [],
1499                         [dnl
1500                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 3rd argument must be either feature or disable])dnl
1501                         ]dnl
1502                 )]dnl
1503         )dnl
1504         AC_ARG_ENABLE(
1505                 [$1],
1506                 AS_HELP_STRING([--$2-$1], [$2 $4 (EnDis by def)]),
1507                 [],
1508                 enable_$1='[YesNo]'dnl
1509         )# AC_ARG_ENABLE
1510 if test "x$enable_$1" = "xno"
1511 then
1512         collectd_$1=0
1513 else
1514         if test "x$enable_$1" = "xyes"
1515         then
1516                 collectd_$1=1
1517         else
1518                 AC_MSG_NOTICE([please specify either --enable-$1 or --disable-$1; enabling $1.])
1519                 collectd_$1=1
1520                 enable_$1='yes'
1521         fi
1522 fi
1523         AC_DEFINE_UNQUOTED([COLLECT_]my_toupper([$1]), [$collectd_$1], [wether or not to enable $3 $4])
1524         AM_CONDITIONAL([BUILD_]my_toupper([$3])[_]my_toupper([$1]), [test "x$enable_$1" = "xyes"])dnl
1525         ]dnl
1526 )# AC_COLLECTD(name, enable/disable, info-text, feature/module)
1527
1528 # AC_PLUGIN(name, default, info)
1529 # ------------------------------------------------------------
1530 dnl
1531 AC_DEFUN(
1532   [AC_PLUGIN],
1533   [
1534     enable_plugin="no"
1535     AC_ARG_ENABLE([$1], AC_HELP_STRING([--enable-$1], [$3]),
1536     [
1537      if test "x$enableval" = "xyes"
1538      then
1539              enable_plugin="yes"
1540      else
1541              enable_plugin="no"
1542      fi
1543     ],
1544     [
1545      if test "x$2" = "xyes"
1546      then
1547              enable_plugin="yes"
1548      else
1549              enable_plugin="no"
1550      fi
1551     ])
1552     if test "x$enable_plugin" = "xyes"
1553     then
1554             AC_DEFINE([HAVE_PLUGIN_]my_toupper([$1]), 1, [Define to 1 if the $1 plugin is enabled.])
1555     fi
1556     AM_CONDITIONAL([BUILD_PLUGIN_]my_toupper([$1]), test "x$enable_plugin" = "xyes")
1557     enable_$1="$enable_plugin"
1558   ]
1559 )# AC_PLUGIN(name, default, info)
1560
1561 m4_divert_once([HELP_ENABLE], [
1562 collectd features:])
1563 # FIXME: Remove these calls to `AC_COLLECTD' and then remove that macro.
1564 AC_COLLECTD([debug],     [enable],  [feature], [debugging])
1565 AC_COLLECTD([daemon],    [disable], [feature], [daemon mode])
1566 AC_COLLECTD([getifaddrs],[enable],  [feature], [getifaddrs under Linux])
1567
1568 plugin_battery="no"
1569 plugin_cpu="no"
1570 plugin_cpufreq="no"
1571 plugin_df="no"
1572 plugin_disk="no"
1573 plugin_entropy="no"
1574 plugin_interface="no"
1575 plugin_irq="no"
1576 plugin_load="no"
1577 plugin_memory="no"
1578 plugin_multimeter="no"
1579 plugin_nfs="no"
1580 plugin_processes="no"
1581 plugin_serial="no"
1582 plugin_swap="no"
1583 plugin_tape="no"
1584 plugin_users="no"
1585 plugin_vserver="no"
1586 plugin_wireless="no"
1587
1588 # Linux
1589 if test "x$ac_system" = "xLinux"
1590 then
1591         plugin_battery="yes"
1592         plugin_cpu="yes"
1593         plugin_cpufreq="yes"
1594         plugin_disk="yes"
1595         plugin_entropy="yes"
1596         plugin_interface="yes"
1597         plugin_irq="yes"
1598         plugin_load="yes"
1599         plugin_memory="yes"
1600         plugin_nfs="yes"
1601         plugin_processes="yes"
1602         plugin_serial="yes"
1603         plugin_swap="yes"
1604         plugin_vserver="yes"
1605         plugin_wireless="yes"
1606 fi
1607
1608 # Mac OS X devices
1609 if test "x$with_libiokit" = "xyes"
1610 then
1611         plugin_battery="yes"
1612         plugin_disk="yes"
1613 fi
1614
1615 # Solaris
1616 if test "x$with_devinfo$with_kstat" = "xyesyes"
1617 then
1618         plugin_cpu="yes"
1619         plugin_disk="yes"
1620         plugin_interface="yes"
1621         plugin_memory="yes"
1622         plugin_swap="yes"
1623         plugin_tape="yes"
1624 fi
1625
1626 # libstatgrab
1627 if test "x$with_libstatgrab" = "xyes"
1628 then
1629         plugin_interface="yes"
1630         plugin_load="yes"
1631         plugin_memory="yes"
1632         plugin_swap="yes"
1633 fi
1634
1635 if test "x$have_processor_info" = "xyes"
1636 then
1637         plugin_cpu="yes"
1638 fi
1639 if test "x$have_sysctlbyname" = "xyes"
1640 then
1641         plugin_cpu="yes"
1642         plugin_memory="yes"
1643 fi
1644
1645 if test "x$have_statfs" = "xyes"
1646 then
1647         plugin_df="yes"
1648 fi
1649 if test "x$have_statvfs" = "xyes"
1650 then
1651         plugin_df="yes"
1652 fi
1653
1654 if test "x$have_getifaddrs" = "xyes"
1655 then
1656         plugin_interface="yes"
1657 fi
1658
1659 if test "x$have_getloadavg" = "xyes"
1660 then
1661         plugin_load="yes"
1662 fi
1663
1664 # Mac OS X memory interface
1665 if test "x$have_host_statistics" = "xyes"
1666 then
1667         plugin_memory="yes"
1668 fi
1669
1670 if test "x$have_termios_h" = "xyes"
1671 then
1672         plugin_multimeter="yes"
1673 fi
1674
1675 if test "x$have_thread_info" = "xyes"
1676 then
1677         plugin_processes="yes"
1678 fi
1679
1680 if test "x$with_libkvm" = "xyes"
1681 then
1682         plugin_swap="yes"
1683 fi
1684
1685 if test "x$have_getutent" = "xyes"
1686 then
1687         plugin_users="yes"
1688 fi
1689 if test "x$have_getutxent" = "xyes"
1690 then
1691         plugin_users="yes"
1692 fi
1693
1694 # FIXME: sysctl for swap plugin
1695
1696 m4_divert_once([HELP_ENABLE], [
1697 collectd plugins:])
1698
1699 AC_PLUGIN([apache],      [$with_libcurl],      [Apache httpd statistics])
1700 AC_PLUGIN([apcups],      [yes],                [Statistics of UPSes by APC])
1701 AC_PLUGIN([apple_sensors], [$with_libiokit],   [Apple's hardware sensors])
1702 AC_PLUGIN([battery],     [$plugin_battery],    [Battery statistics])
1703 AC_PLUGIN([cpu],         [$plugin_cpu],        [CPU usage statistics])
1704 AC_PLUGIN([cpufreq],     [$plugin_cpufreq],    [CPU frequency statistics])
1705 AC_PLUGIN([csv],         [yes],                [CSV output plugin])
1706 AC_PLUGIN([df],          [$plugin_df],         [Filesystem usage statistics])
1707 AC_PLUGIN([disk],        [$plugin_disk],       [Disk usage statistics])
1708 AC_PLUGIN([dns],         [$with_libpcap],      [DNS traffic analysis])
1709 AC_PLUGIN([email],       [yes],                [EMail statistics])
1710 AC_PLUGIN([entropy],     [$plugin_entropy],    [Entropy statistics])
1711 AC_PLUGIN([exec],        [yes],                [Execution of external programs])
1712 AC_PLUGIN([hddtemp],     [yes],                [Query hddtempd])
1713 AC_PLUGIN([interface],   [$plugin_interface],  [Interface traffic statistics])
1714 AC_PLUGIN([iptables],    [$with_libiptc],      [IPTables rule counters])
1715 AC_PLUGIN([irq],         [$plugin_irq],        [IRQ statistics])
1716 AC_PLUGIN([load],        [$plugin_load],       [System load])
1717 AC_PLUGIN([logfile],     [yes],                [File logging plugin])
1718 AC_PLUGIN([mbmon],       [yes],                [Query mbmond])
1719 AC_PLUGIN([memory],      [$plugin_memory],     [Memory usage])
1720 AC_PLUGIN([multimeter],  [$plugin_multimeter], [Read multimeter values])
1721 AC_PLUGIN([mysql],       [$with_libmysql],     [MySQL statistics])
1722 AC_PLUGIN([netlink],     [$with_libnetlink],   [Enhanced Linux network statistics])
1723 AC_PLUGIN([network],     [yes],                [Network communication plugin])
1724 AC_PLUGIN([nfs],         [$plugin_nfs],        [NFS statistics])
1725 AC_PLUGIN([ntpd],        [yes],                [NTPd statistics])
1726 AC_PLUGIN([nut],         [$with_libupsclient], [Network UPS tools statistics])
1727 AC_PLUGIN([perl],        [$with_libperl],      [Embed a Perl interpreter])
1728 AC_PLUGIN([ping],        [$with_liboping],     [Network latency statistics])
1729 AC_PLUGIN([processes],   [$plugin_processes],  [Process statistics])
1730 AC_PLUGIN([rrdtool],     [$with_rrdtool],      [RRDTool output plugin])
1731 AC_PLUGIN([sensors],     [$with_lm_sensors],   [lm_sensors statistics])
1732 AC_PLUGIN([serial],      [$plugin_serial],     [serial port traffic])
1733 AC_PLUGIN([snmp],        [$with_libnetsnmp],   [SNMP querying plugin])
1734 AC_PLUGIN([swap],        [$plugin_swap],       [Swap usage statistics])
1735 AC_PLUGIN([syslog],      [$have_syslog],       [Syslog logging plugin])
1736 AC_PLUGIN([tape],        [$plugin_tape],       [Tape drive statistics])
1737 AC_PLUGIN([unixsock],    [yes],                [Unixsock communication plugin])
1738 AC_PLUGIN([users],       [$plugin_users],      [User statistics])
1739 AC_PLUGIN([vserver],     [$plugin_vserver],    [Linux VServer statistics])
1740 AC_PLUGIN([wireless],    [$plugin_wireless],   [Wireless statistics])
1741 AC_PLUGIN([xmms],        [$with_libxmms],      [XMMS statistics])
1742
1743 AC_OUTPUT(Makefile src/Makefile src/collectd.conf src/liboconfig/Makefile src/liboping/Makefile)
1744
1745 if test "x$with_liboping" = "xyes" -a "x$with_own_liboping" = "xyes"
1746 then
1747         with_liboping="yes (shipped version)"
1748 fi
1749
1750 if test "x$with_libperl" = "xyes"
1751 then
1752         with_libperl="yes (version `perl -MConfig -e 'print $Config{version};'`)"
1753 else
1754         enable_perl="no (needs libperl)"
1755 fi
1756
1757 cat <<EOF;
1758
1759 Configuration:
1760   Libraries:
1761     libcurl . . . . . . $with_libcurl
1762     libiokit  . . . . . $with_libiokit
1763     libiptc . . . . . . $with_libiptc
1764     libkstat  . . . . . $with_kstat
1765     libkvm  . . . . . . $with_libkvm
1766     libmysql  . . . . . $with_libmysql
1767     libnetlink  . . . . $with_libnetlink
1768     libnetsnmp  . . . . $with_libnetsnmp
1769     liboconfig  . . . . $with_liboconfig
1770     liboping  . . . . . $with_liboping
1771     libpcap . . . . . . $with_libpcap
1772     libperl . . . . . . $with_libperl
1773     libpthread  . . . . $with_libpthread
1774     librrd  . . . . . . $with_rrdtool
1775     libsensors  . . . . $with_lm_sensors
1776     libstatgrab . . . . $with_libstatgrab
1777     libupsclient  . . . $with_libupsclient
1778     libxmms . . . . . . $with_libxmms
1779
1780   Features:
1781     daemon mode . . . . $enable_daemon
1782     debug . . . . . . . $enable_debug
1783
1784   Modules:
1785     apache  . . . . . . $enable_apache
1786     apcups  . . . . . . $enable_apcups
1787     apple_sensors . . . $enable_apple_sensors
1788     battery . . . . . . $enable_battery
1789     cpu . . . . . . . . $enable_cpu
1790     cpufreq . . . . . . $enable_cpufreq
1791     csv . . . . . . . . $enable_csv
1792     df  . . . . . . . . $enable_df
1793     disk  . . . . . . . $enable_disk
1794     dns . . . . . . . . $enable_dns
1795     email . . . . . . . $enable_email
1796     entropy . . . . . . $enable_entropy
1797     exec  . . . . . . . $enable_exec
1798     hddtemp . . . . . . $enable_hddtemp
1799     interface . . . . . $enable_interface
1800     iptables  . . . . . $enable_iptables
1801     irq . . . . . . . . $enable_irq
1802     load  . . . . . . . $enable_load
1803     logfile . . . . . . $enable_logfile
1804     mbmon . . . . . . . $enable_mbmon
1805     memory  . . . . . . $enable_memory
1806     multimeter  . . . . $enable_multimeter
1807     mysql . . . . . . . $enable_mysql
1808     netlink . . . . . . $enable_netlink
1809     network . . . . . . $enable_network
1810     nfs . . . . . . . . $enable_nfs
1811     ntpd  . . . . . . . $enable_ntpd
1812     nut . . . . . . . . $enable_nut
1813     perl  . . . . . . . $enable_perl
1814     ping  . . . . . . . $enable_ping
1815     processes . . . . . $enable_processes
1816     sensors . . . . . . $enable_sensors
1817     serial  . . . . . . $enable_serial
1818     snmp  . . . . . . . $enable_snmp
1819     swap  . . . . . . . $enable_swap
1820     syslog  . . . . . . $enable_syslog
1821     tape  . . . . . . . $enable_tape
1822     unixsock  . . . . . $enable_unixsock
1823     users . . . . . . . $enable_users
1824     vserver . . . . . . $enable_vserver
1825     wireless  . . . . . $enable_wireless
1826     xmms  . . . . . . . $enable_xmms
1827
1828 EOF